People said:

Last, and certainly not least was Sacha Chua. If we could harness it I’m pretty sure we could power a few small cities of the energy that’s contained in this one, tiny person – especially when you get her talking about Emacs. Sacha’s demo, entitled, “Livin’ la vida Emacs” was hands down the most entertaining of the evening. Sacha has basically taken this simple, extendable text editor and pushed it about as far as it can go – at DemoCamp10 she pulled back the curtain and showed us all her little systems and apps she’s created in it. I like my GUI/Windows so the whole text-based thing isn’t for me but it certainly was interesting to see just how strung out she’s got that machine.

Ryan Coleman

Sacha Chua showed off what can be done in the scriptable environment, in this case emacs, as she went from Text editor, to a.i. doctor, to game engine to task / email organizer and beyond. Sacha was six feet tall on that stage, even though she did not actual levitate at anytime (although she came close, as always). A Tour de force of the Emacs, a text editing tool built in a interpreted lisp language environment, bascially a personalized productivity platform which allows for massive customization. Sacha had the crowd entertained and enthralled. (Sacha blogged her own impressions and mentions that Emacs was speaking to her!)

Ian Irving

Within Toronto’s Web community, Sacha Chua has become one of the leading “personalities”. Armed with infectious enthusiasm, charm and smarts, she would be an excellent person to hire once she graduates from UoT. The key question is how best to use her talents. It would probably be as a customer service rep, who can come into a bad situation and get everyone happy by the time she leaves. If I was an HR person from Microsoft, IBM, etc. I’d be knocking on Sacha’s door ASAP.

Mark Evans, consultant

Why? Probably because in addition to my natural sugar high, I was also presenting something that was awesomely, arcanely geeky. =)

I hadn’t figured out how to make a screencast on Linux, so the actual display on my screen is lost to time. I do, however, have the source code that I used to step through my speech–including speaking cues, as I didn’t want to mess up the presentation in front of Toronto’s technorati! So here’s the source code, for your amusement. I set up two of my function keys to go forward and backward, executing the parenthesized expressions. I also set up a hidden window that could handle my speaking cues so that Emacs could remind me what the next “slide” was before I transitioned to it, for smoother flow. emacspeak-speak-buffer is a function that reads the current window’s text using the Emacspeak speech interface with the Festival synthesizer I’d configured. At some point, I switched to a more interactive demo, but I still had the speaking cues remind me of the sequence. So yes, Emacs really was telling me what to say.

;; Emacs as a text editor

(progn ;; Setup
  (defvar democamp/presentation-file "~/democamp.el")
  (defvar democamp/cue-buffer "*DemoCamp*")
  (defun democamp/next ()
    (interactive)
    (let (start sexp)
      (with-current-buffer (find-file-noselect democamp/presentation-file)
        (setq start (point))
        (forward-sexp)
        (setq sexp (buffer-substring-no-properties start (point))))
      (eval (read sexp))))

  (defun democamp/previous ()
    (interactive)
    (let (start sexp)
      (with-current-buffer (find-file-noselect democamp/presentation-file)
        (setq start (point))
        (backward-sexp)
        (setq sexp (buffer-substring-no-properties (point) start)))
      (eval (read sexp))))

  (defun democamp/repeat ()
    (interactive)
    (let (start sexp)
      (with-current-buffer (find-file-noselect democamp/presentation-file)
        (setq start (point))
        (backward-sexp)
        (setq sexp (buffer-substring (point) start))
        (forward-sexp))
      (eval (read sexp))))

  (defun democamp/say (text)
    (with-current-buffer (get-buffer-create democamp/cue-buffer)
      (erase-buffer)
      (insert text)
      (goto-char (point-min))
      (call-interactively 'emacspeak-speak-buffer)))
  (global-set-key (kbd "<f12>") 'democamp/next)
  (global-set-key (kbd "S-<f12>") 'democamp/previous)
  (global-set-key (kbd "C-<f12>") 'democamp/repeat)
)

;; Window register a
(progn
  (menu-bar-mode 1)
  (tool-bar-mode 1)
  (set-face-attribute 'default nil :height 200)
  (find-file "~/hello.txt")
  (democamp/say "I don't know why people are so intimidated by Emacs. It's a text editor. It has menus and toolbars and everything.")
  (frame-configuration-to-register ?a)) 

(progn
  (democamp/say "Spell-check, too.")
  (load-library "flyspell")
  (load-library "emacspeak-flyspell")
  (setq emacspeak-flyspell-highlight-personality nil)
  (flyspell-mode 1))

;; Emacs learning curve
;; Frame configuration b
(progn
  (find-file "~/tmp/learningcurves.jpg")
  (democamp/say "So why are people terrified of Emacs?"))

(progn
  (set-face-attribute 'default nil :height 700)
  (delete-other-windows)
  (sit-for 1)
  (animate-sequence (list "Livin' la Vida Emacs" "DemoCamp10" "Sacha Chua" "Oct 23, 2006") 1))

(progn
  (set-face-attribute 'default nil :height 200)
  (democamp/say "Emacs comes with a psychotherapist.")
  (doctor))
(progn
  (democamp/say "an adventure game")
  (dunnet))
(progn
  (democamp/say "random geek stuff")
  (hanoi 3))
(progn
  (democamp/say "even Snake")
  (delete-other-windows)
  (snake))
(progn
  (democamp/say "And of course, my favorite game, Nethack.")
  (load-library "nethack-config")
  (nethack))
(democamp/say "Some of it is useful")
;; Flashcard
(progn
  (democamp/say "Flashcards")
  (load-library "flashcard-config")
  (find-file "~/notebook/japan/japanese.deck")
  (goto-char (point-max)))
;; With fortunes
(progn
  (democamp/say "And you can mash things together")
  (load-library "fortune")
  (setq fortune-file "/usr/share/games/fortunes/computers")
  (fortune)
  (delete-other-windows))
(progn
  (find-file-other-window "~/notebook/japan/japanese.deck")
  (goto-char (point-max)))

;; Planner
(democamp/say "Now the wild stuff starts.")
(progn
  (planner-goto-today)
  (delete-other-windows)
  (democamp/say "Emacs: more than just an editor. It's a way of life."))

;; - Show tasks
(democamp/say "I use Emacs to manage my tasks with Planner.")
(democamp/say "I can even keep detailed time logs!")
(progn
  (load-library "/usr/src/planner-el/planner-timeclock-summary.el")
  (planner-timeclock-summary-show (planner-today)))

;; - Show notes
(democamp/say "... blog...")
;; - Jump to URL in w3m
(democamp/say "... surf the Web (with tabbed browsing and a custom keymap!)")
33;; - Jump to URL in Firefox
(democamp/say "Although sometimes you really want Firefox.")
;; - Jump to task from mail message
(democamp/say "I can hyperlink to pretty much anything.")
(democamp/say "People's contact information")
(democamp/say "E-mail, etc.")
(democamp/say "Which comes in handy when I need to create tasks from mail messages.")
;; Add note to BBDB from mail message
(progn
  (democamp/say "Keeping track of the number of recipients")
  (planner-visit-link "pos://~/.gnus#19820"))
(democamp/say "BBDB indicators")

;; Reply to message with nickname,
(progn
  (democamp/say "CRM in e-mail: Nicknames...")
  (planner-visit-link "pos://~/.gnus#16025"))

;; and show how it shows up in BBDB record and ping code
(progn
  (democamp/say "... notes...")
  (planner-visit-link "pos://~/.gnus#18804"))

(progn
  (democamp/say "... pings...")
  (planner-visit-link "pos://~/.gnus#16932"))

(democamp/say "... filters...")
(democamp/say "So those are just a few examples of the crazy stuff you can do if you have an infinitely tweakable environment.")
(democamp/say "Sacha, remember to plug in the speakers.")
(democamp/say "Demo Campers, welcome to Emacs. What else do you want it to do?")

I love pushing the envelope. I love getting to know my tools inside and out (I enjoy reading source code!) and then making them do things other people can’t imagine. I love tweaking processes in real life, too, making them better and better every time. That’s just part of the way I work have fun. =)

How can you rock your next technical demo?

Post from: sacha chua :: enterprise 2.0 consultant, storyteller, geek. Check out my blog for tips on managing virtual assistants, Drupal, and other topics!

Behind the scenes: Livin’ la Vida Emacs

After a few pages of editing (and correcting the occasional typo that crept in as I changed URLs), I decided to partially automate the process. Using a smidgen of Emacs Lisp, I created a function that pasted text into a temporary buffer, performed whatever automatic fixes it could make, prompted me for any URLs it didn’t recognize, remembered the old URL – new URL mapping I defined, and copied the text back.

The function looked somewhat like this:

(defvar sacha/wiki-links nil "Associative list of (old-url . new-url).")
(defun sacha/wiki-fix ()
  (interactive)
  (with-temp-buffer
    ;; Insert text from clipboard
    (yank)
    (goto-char (point-min))
    ;; Look for all the links
    (while (re-search-forward
            "\\[\\([^|]+\\)|\\([^\]]+\\)\\]" nil t)
      ;; Check if it's one of the links I want to replace
      (if (or (string-match-p "viewpage" (match-string 2))
              (string-match-p "lsoohoo" (match-string 2)))
          (replace-match
           (save-match-data
             ;; Prompt and the entry to the map if it does not yet exist
             (unless (assoc (match-string 2) sacha/wiki-links)
               (add-to-list 'sacha/wiki-links
                            (cons (match-string 2)
                                  (read-string (concat (match-string 1)
                                                       "? ")))))
             ;; pick up the corresponding URL
             (cdr (assoc (match-string 2) sacha/wiki-links)))
           t t nil 2)))
    ;; Copy the text into the clipboard
    (kill-new (buffer-string))))

I used M-x global-set-key to bind a convenient function key to it (F12, I think), and then it was just a matter of clicking on each page, clicking on Edit, typing Ctrl-C to copy the text, switching to Emacs, pressing F12, switching back to my browser, typing Ctrl-V, and saving the wiki page. I also added some lines (not shown here) to convert the previous wiki gardener’s full links to intrawiki links, change server URLs, and do other fun things.

I thought about fully automating it (somehow hooking into w3, perhaps?), but that seemed to be more trouble than needed. Besides, it was good to review all the pages.

As a result of this Emacs wizardry, processing all 149 wiki pages took me a few hours instead of a few days. Yay!

Of course, I finished the last wiki page, I found out that I needed to change the servers in the URL. I decided to go ahead and fully automate the darn thing.

I extracted a list of URLs for the wiki by viewing the tree version of the wiki index. It used Javascript, so I couldn’t just pull the URLs out of the source code. Fortunately, the Firebug plugin for Firefox lets me copy the rendered HTML, so I used that instead. Some judicious text-editing later (replace-regexp rocks), I had a list of URLs to the different pages. I knew I needed to put in some kind of delay when loading web pages. sleep-for let me spread out my requests so I didn’t hammer the server too badly. Reading the w3m.el source code turned up w3m-async-exec. Once I set that to nil, requesting web pages and running code on the results turned out to be straightforward. Selecting the right widgets was a bit of a hack (re-search-forward here, w3m-previous-anchor there), but hey, it worked. After confirming it by manually running it on a few pages, I left it merrily running in the background.

Here it is (some tweaking required):

(defun sacha/edit-wiki-page ()
  (interactive)
  (let ((buffer (current-buffer))
        (w3m-async-exec nil)
        (delay 5)) ;; number of seconds
    ;; While not at the end of the buffer
    (while (not (eobp))
      ;; Load the URL on the current line
      (w3m-browse-url
       (buffer-substring
        (line-beginning-position)
        (line-end-position)))
      ;; Look for the edit button
      (goto-char (point-min))
      (when (search-forward "Edit" nil t)
        ;; Click it
        (w3m-view-this-url)
        ;; Look for the Minor change checkbox
        (goto-char (point-min))
        (when (search-forward "Minor change" nil t)
          ;; The text area is the second widget back
          (w3m-previous-anchor 2)
          ;; Open the text area in a temporary buffer for editing
          (w3m-view-this-url)
          ;; Do the changes
          (while (re-search-forward "https?://example.com/path" nil t)
            (replace-match "http://path.example.com" t t nil 0))
          ;; Save the value
          (w3m-form-input-textarea-set)
          (when (search-backward "Save" nil t)
            (w3m-view-this-url))))
      (switch-to-buffer buffer)
      (forward-line)
      (sleep-for delay))))

I’m sure this kind of automation might be possible with lots of hacking in Mozilla Firefox, and I’ve seen great scripts for the Mac, too. But I know Emacs, I’m comfortable digging into source code, and I can make things work.

Awesome. =D

Post from: sacha chua :: enterprise 2.0 consultant, storyteller, geek. Check out my blog for tips on managing virtual assistants, Drupal, and other topics!

Automating tedious wiki editing tasks with Emacs and w3m

I miss writing in wiki markup on Emacs and knowing that publishing would Just Work. I miss being able to dynamically expand entries from my address book in a way that automatically links to people’s blogs. (Or Twitter accounts, if I were going to do this now.) ScribeFire is a pain on my Eee (needs more horizontal screen space), and I have a hard time marking up the occasional bit of HTML in weblogger.el. Windows Live Writer is pretty slick (particularly with the SnagIt Screen Capture plugin and the Amazon Book Linker), but I can live without it. Or maybe I can resurrect that Wordpress Emacs client Ashish mentioned.

Let me think about the differences in experiences.

• I wanted to support comments, but I didn’t want to spend a lot of time hacking on some custom commenting system. This was a big issue for me. I found some commenting scripts, but dealing with spam was a pain, so I switched to Wordpress. If I switched back to Emacs for my blog, I’d probably use something like Disqus to handle the conversation, and just find some way of backing up the comments regularly.
• I wanted to make it easy to navigate posts. I modified Planner to generate a more browsable blog index, but it’s still not as slick as what you’d see with Wordpress. On this Wordpress blog, I like offering people random blog posts (good for me too – great way to rediscover old posts and make serendipitous connections!), related posts, and posts on the same day. I can do posts on the same day in Planner with a custom hook, but the others would require some hacking. Also, Planner is very much day-based, while Wordpress lists N posts per page and has good category lists.
• I wanted to make it easy to edit posts. In my Emacs-based system, I published to RSS when I saved a note in the Remember window. I had a hack that made it possible to propagate changes from an already-published post to my Wordpress blog, but it wasn’t completely reliable.
• Scheduling posts is handy, too. I hadn’t gotten around to figuring out how to build a post scheduler for Emacs. I suppose if I wasn’t picky about the time it went out, I could simply write posts on different days and then publish notes conditionally, plus have some kind of hook to notice if any of the current page’s posts should be published in the RSS feed, plus some way to handle previous days, plus maybe a server-friendly way to do this for the times when I’m not going to be online every day. Right.

That said, I miss automatically sharing some details of what I’m working on (with details deleted before publishing so that they’re available offline), publicly crossing off tasks, and other cool things.

Planner’s model for task planning isn’t quite compatible with Org’s model, and I’ve been using Org + Toodledo more these days.

What am I really looking for here?

• A quick, reliable way to post from a text editor, so that I can do it from the Eee. Hmm, the WP Postie plugin will probably do the trick.
• Easy way to share/review tasks: Toodledo export of week’s tasks?
• And maybe a custom plugin for weekly displays, org agendas, that sort of thing.

Hmm….

Post from: sacha chua :: enterprise 2.0 consultant, storyteller, geek. Check out my blog for tips on managing virtual assistants, Drupal, and other topics!

Thinking about Planner/EmacsWiki versus Wordpress

I still like Toodledo, but I feel an unsatisfied itch. Toodle-do is a great Getting Things Done system for capturing and tracking tasks, but even though it has some support for defining short-, medium-, and long-term goals, I wasn’t using them because they were split up on multiple screens. I missed the outlines of Org where I could define my higher-level goals, easily add new ones, and create tasks and subtasks. I missed the close integration with my schedule and the ability to easily see my historical task information. I missed the distinction between scheduled dates and deadlines, and the calculation of days until something is due.

So I think it’s time to switch back, at least temporarily. Maybe I can find a way to seamlessly synchronize my Org files so that changes are reflected on the different computers I’m on, and maybe I can find a way to easily capture or review tasks while I’m on the go. Perhaps I’ll continue working on org-toodledo so that I can export tasks from Org to the web-based interface. That way, I can quickly review today’s tasks while I’m out and about.

Hmm…

Post from: sacha chua :: enterprise 2.0 consultant, storyteller, geek. Check out my blog for tips on managing virtual assistants, Drupal, and other topics!

Thoughts on Toodledo versus Emacs Org

Here’s what I like about the other services:

• Both Remember the Milk and Toodledo have iPhone/iPod Touch interfaces, so I can review, check off, and create tasks anywhere.
• All those services allow me to e-mail tasks to an address.
• It’s easy to filter tasks by context.
• I can share my tasks with my assistant so that he or she can remind me of the tasks I’ve scheduled for the day.

Here’s what I like about Org:

• I can use templates and outlines to organize my tasks however I want.
• I can set deadlines, scheduled tasks, and prior notice easily.
• I can track time more finely than Toodledo can.
• I can use Org as an activity log.
• I can schedule tasks onto specific timeslots.

Of all the options I’ve tried, Toodledo is closest to where I am with Org, although it still doesn’t do everything.

Some options are:

• Use worg or develop a web-based interface for displaying tasks based on my Org file
• Write code for synchronizing Org with Toodledo or RememberTheMilk, making lots of geeks happy in the process =)

Post from: sacha chua :: enterprise 2.0 consultant, storyteller, geek. Check out my blog for tips on managing virtual assistants, Drupal, and other topics!

Nothing quite like Org for Emacs

For example, last week, I needed to coordinate schedules with Katie Bartlett, Jeff Widman’s assistant, for a chat with Jeff about networking. I thought about how much e-mail was sent back-and-forth figuring out times and timezones, and I multiplied that by the number of appointments Katie probably needed to arrange. That sounded like a lot of work. If I could find a tool to make that easier for our appointment, and she used that tool to organize lots of other appointments, then that would be great!

I checked out a couple of tools such as TimeToMeet, ScheduleOnce, and AgreeADate. Of the tools I tried, I liked AgreeADate the most because it made it easy to create different kinds of schedules and it supported timezones. I sent Katie a few potential timeslots for my chat with Jeff. After she replied, I confirmed the time that was mutually convenient. That wasn’t hard at all.

Then I explored the other features. I found out that I could create a schedule where people could pick a slot. AgreeADate allowed me to specify how many people each timeslot was limited to, and how many slots people could choose. This opened up all sorts of possibilities, and has become my favorite feature!

Things that I’d formerly had been worried about scheduling became so much easier to schedule because I could create all the slots in parallel and then let people choose the slots that hadn’t been taken yet. For example, I’d been meaning to try outsourcing some technical and personal tasks, but scheduling interview times sounded like a hassle. With this system, I just had to set all the slots up and invite people to choose the timeslot most convenient for them. Yay!

AgreeADate isn’t perfect, but it makes scheduling things so much easier for me, and it lowers the barrier enough for me to go and make things happen. In the past week that I’ve been trying it out, I’ve:

• scheduled a capoeira trial
• scheduled a conference call
• set up interviews for a system administrator and a virtual assistant, and
• set up lunch with a poll on where to eat.

You know, stuff that would’ve taken way too much e-mail if I had to do it by hand. =)

I’d like to see it integrated with my Google Calendar, and one of the AgreeADate folks told me that that’s the next thing on their roadmap. I found myself wondering which slots I’d tentatively offered for other events, and being able to see all the tentative slots overlaid on my calendar would be fantastic.

In the meantime, I read the confirmation e-mails in Emacs Gnus, use Remember and Org to create an appointment hyperlinked to that mail, and then use my own code, the twit.el library, and the Twittercal service to create an appointment on my Google Calendar (on google.com), which is then shared with my Google Calendar on sachachua.com thanks to the joys of Google Apps. It’s quite Rube Goldberg-esque (as many of my bubblegum-and-string tricks are), but so far, it works. Maybe this’ll be something I’ll outsource (except perhaps without the Gnus + Remember + Org part) once I’ve gotten that virtual assistance thing sorted out. =)

For the geeks, some Emacs Lisp to mash together with Org, TwitterCal, Google Calendar, and twit.el (some wizardry required):

(defun sacha/org-as-gcal-quick-add ()
  "Convert the current SCHEDULED: timestamp and header into a GCal quick add item."
  (save-excursion
    (org-back-to-heading t)
    (setq end (save-excursion (outline-next-heading) (point)))
    (when (re-search-forward org-scheduled-time-regexp
			     end t)
      (let (ts default-time stamp plain s0 srp s1 s2)
	(setq ts (match-string 1)
	      default-time (apply 'encode-time (org-parse-time-string ts)))
	(when (or (setq stamp (string-match org-stamp-time-of-day-regexp ts))
		  (setq plain (string-match org-plain-time-of-day-regexp ts)))
	  (setq s0 (match-string 0 ts)
		srp (and stamp (match-end 3))
		s1 (match-string (if plain 1 2) ts)
		s2 (match-string (if plain 8 (if srp 4 6)) ts)))
	(cond
	 (s2
	  (concat (org-no-properties (org-get-heading t)) " on "
		  (format-time-string "%x" default-time) " from "
		  (org-get-time-of-day s1 'string t) " to "
		  (org-get-time-of-day s2 'string t)
		  ))
	 (s1

	  (concat (org-no-properties (org-get-heading t)) " on "
		  (format-time-string "%x" default-time) " from "
		  (org-get-time-of-day s1 'string t)
		  ))
	 (t
	  (concat (org-no-properties (org-get-heading t)) " on "
		  (format-time-string "%x" default-time)
		  )
	  ))))))

(defun sacha/org-to-twittercal (string)
  "Post STRING to TwitterCal. See http://www.twittercal.com for details."
  (interactive (list (read-string "Event: " (sacha/org-as-gcal-quick-add))))
  (twit-post-function twit-update-url (concat "d gcal " string)))

I’ll keep you posted on my experiments! =)

Post from: sacha chua :: enterprise 2.0 consultant, storyteller, geek. Check out my blog for tips on managing virtual assistants, Drupal, and other topics!

Planning meetings, get-togethers, and interviews with AgreeADate

Abstract:

Are you a lazy developer? If you aren’t, you should be! Find out about editor tricks that can save you hours and hours of effort and frustration. Learn about browser tips that make it easy to test your sites with different users, track down elusive bugs, and test. Develop the virtue of laziness by automating as much as you can with makefiles, the Drupal Shell, regression tests, and other goodies. Share your best tips during this interactive session. Use your new free time to rock even more!

Bio

Sacha Chua has an unshakable belief that life is too short to waste doing repetitive tasks that can be automated, an irrational love for tweaking her development environment, and an irresistible urge to share whatever she’s learned along the way. To learn more about her and Web 2.0, Drupal, Emacs, and other things she’s interested, visit [INTERNAL IBM URL] or http://LivingAnAwesomeLife.com (personal blog).

Inside IBM and want to get a copy of the calendar invite? Contact William Shaouy.

Post from: sacha chua :: enterprise 2.0 consultant, storyteller, geek. Check out my blog for tips on managing virtual assistants, Drupal, and other topics!

Upcoming talk: Totally Rocking Your Drupal Development Environment

To change the background color and other attributes, use the command M-x customize-face, and specify default as the face to customize. Change the attributes and the sample text will reflect your settings. When you are satisfied, select Save for future sessions. Your changes will be saved to ~/.emacs and reloaded the next time you start the editor.

This is a draft for Wicked Cool Emacs, a book that will be published by No Starch Press. (if we manage to get it all together! =)

Post from: sacha chua :: enterprise 2.0 consultant, storyteller, geek. Check out my blog for tips on managing virtual assistants, Drupal, and other topics!

Emacs basics: Changing the background color

Post from: sacha chua :: enterprise 2.0 consultant, storyteller, geek. Check out my blog for tips on managing virtual assistants, Drupal, and other topics!

Emacs, file-cache, and ido

With an awesome development environment like my customized Emacs, however, I can easily juggle multiple source trees. Here’s the macro I wrote to make setting this up much easier:

(defmacro sacha/file-cache-setup-tree (prefix shortcut directories)
  "Set up the file-cache tree for PREFIX using the keyboard SHORTCUT.
DIRECTORIES should be a list of directory names."
  `(let ((file-cache-alist nil)
	 (directories ,directories))
     (file-cache-clear-cache)
     (while directories
       (file-cache-add-directory-using-find (car directories))
       (setq directories (cdr directories)))
     (setq ,(intern (concat "sacha/file-cache-" prefix "-alist")) file-cache-alist)
     (defun ,(intern (concat "sacha/file-cache-ido-find-" prefix)) ()
       (interactive)
       (let ((file-cache-alist ,(intern (concat "sacha/file-cache-" prefix "-alist"))))
	 (call-interactively 'file-cache-ido-find-file)))
     (global-set-key (kbd ,shortcut)
		     (quote ,(intern (concat "sacha/file-cache-ido-find-" prefix))))))

With that, I can use the following to map C-c p to finding files in my personal directories:

(sacha/file-cache-setup-tree
 "personal"
 "C-c p"
 '("/var/www/html/drupal"
   "~/elisp"
   "~/personal"))

I’ve also set up keyboard shortcuts for the other trees I’m working on.

You’ll need file-cache, ido, and probably something like this:

(require 'filecache)
(require 'ido)
(defun file-cache-ido-find-file (file)
  "Using ido, interactively open file from file cache'.
First select a file, matched using ido-switch-buffer against the contents
in `file-cache-alist'. If the file exist in more than one
directory, select directory. Lastly the file is opened."
  (interactive (list (file-cache-ido-read "File: "
                                          (mapcar
                                           (lambda (x)
                                             (car x))
                                           file-cache-alist))))
  (let* ((record (assoc file file-cache-alist)))
    (find-file
     (expand-file-name
      file
      (if (= (length record) 2)
          (car (cdr record))
        (file-cache-ido-read
         (format "Find %s in dir: " file) (cdr record)))))))

(defun file-cache-ido-read (prompt choices)
  (let ((ido-make-buffer-list-hook
	 (lambda ()
	   (setq ido-temp-list choices))))
    (ido-read-buffer prompt)))
(add-to-list 'file-cache-filter-regexps "docs/html")
(add-to-list 'file-cache-filter-regexps "\\.svn-base$")
(add-to-list 'file-cache-filter-regexps "\\.dump$")

Post from: sacha chua :: enterprise 2.0 consultant, storyteller, geek. Check out my blog for tips on managing virtual assistants, Drupal, and other topics!

Emacs: Working with multiple source trees

I switched to Wordpress for my blog because I got tired of trying to figure out a way to enable comments without getting mired in spam-fighting. That meant I could explore other Emacs personal information managers like Org, which I turned into my main task manager. I often used the Wordpress interface to write blog posts. I sometimes used Windows Live Writer to write posts about books (there’s a good book review plugin that makes this easy). I also sometimes used Emacs and Org to draft blog posts using Org’s friendlier markup, exporting snippets to HTML that I then pasted into my blog posts.

Reading the posts on Planet Emacsen reminded me that my customized configuration was pretty darn sweet. That and the conversation notes I’ve been blogging lately encouraged me to dust off my configuration files and get them to work under Org. So here’s the code:

 (defun sacha/org-bbdb-get (path)
   "Return BBDB record for PATH."
   (car (bbdb-search (bbdb-records) path path path)))

 (defun sacha/org-bbdb-export (path desc format)
   "Create the export version of a BBDB link specified by PATH or DESC.
 If exporting to HTML, it will be linked to the person's blog,
 www, or web address. If exporting to LaTeX FORMAT the link will be
 italicised. In all other cases, it is left unchanged."
     (cond
      ((eq format 'html)
       (let* ((record
             (sacha/org-bbdb-get path))
            url)
       (setq url (and record
                      (or (bbdb-record-getprop record 'blog)
                          (bbdb-record-getprop record 'www)
                          (bbdb-record-getprop record 'web))))
       (if url
           (format "<a href=\"%s\">%s</a>"
                   url (or desc path))
         (format "<em>%s</em>"
                 (or desc path)))))
      ((eq format 'latex) (format "\\textit{%s}" (or desc path)))
      (t (or desc path))))

 (defadvice org-bbdb-export (around sacha activate)
   "Override org-bbdb-export."
   (setq ad-return-value (sacha/org-bbdb-export path desc format)))

 ;;;_+ Hippie expansion for BBDB; map M-/ to hippie-expand for most fun
 (add-to-list 'hippie-expand-try-functions-list 'sacha/try-expand-bbdb-annotation)
 (defun sacha/try-expand-bbdb-annotation (old)
   "Expand from BBDB. If OLD is non-nil, cycle through other possibilities."
   (unless old
     ;; First time, so search through BBDB records for the name
     (he-init-string (he-dabbrev-beg) (point))
     (when (> (length he-search-string) 0)
       (setq he-expand-list nil)
       (mapcar
        (lambda (item)
        (let ((name (bbdb-record-name item)))
          (when name
            (setq he-expand-list
                  (cons (org-make-link-string
                       (org-make-link "bbdb:" name)
                       name)
                        he-expand-list)))))
        (bbdb-search (bbdb-records)
                     he-search-string
                     he-search-string
                     he-search-string
                     nil nil))))
   (while (and he-expand-list
               (or (not (car he-expand-list))
                   (he-string-member (car he-expand-list) he-tried-table t)))
     (setq he-expand-list (cdr he-expand-list)))
   (if (null he-expand-list)
       (progn
         (if old (he-reset-string))
         nil)
     (progn
       (he-substitute-string (car he-expand-list) t)
       (setq he-expand-list (cdr he-expand-list))
       t)))

If you’ve got Org and BBDB, drop this into your ~/.emacs and fiddle with it. =)

Post from: sacha chua :: enterprise 2.0 consultant, storyteller, geek. Check out my blog for tips on managing virtual assistants, Drupal, and other topics!

Emacs, Org, and BBDB: Hyperlinking names to blogs

(defun wicked/w3m-open-current-page-in-firefox ()
  "Open the current URL in Mozilla Firefox."
  (interactive)
  (browse-url-firefox w3m-current-url)) ;; (1)

(defun wicked/w3m-open-link-or-image-in-firefox ()
  "Open the current link or image in Firefox."
  (interactive)
  (browse-url-firefox (or (w3m-anchor) ;; (2)
                          (w3m-image)))) ;; (3)

This defines a function that uses the current URL being browsed(1) and another function that takes the URL of the link at point(2). If no link is found, it takes the URL of the image at point(3).

You can use other browse-url functions instead of browse-url-firefox. For example, replacing browse-url-firefox with browse-url-kde will open the page, link, or image in Konqueror, KDE’s web browser.

I like binding f to the function that opens the current URL in Mozilla Firefox and F to the function that opens the current link or image in Mozilla Firefox. To do the same, add the following to your ~/.emacs:

(eval-after-load 'w3m
  (progn
    (define-key w3m-mode-map "f" 'wicked/w3m-open-current-page-in-firefox)
    (define-key w3m-mode-map "F" 'wicked/w3m-open-link-or-image-in-firefox)))

—
This is part of the book that I’m writing about Emacs, which will be published by No Starch Press if I manage to get it together in time.

Post from: sacha chua :: enterprise 2.0 consultant, storyteller, geek. Check out my blog for tips on managing virtual assistants, Drupal, and other topics!

Emacs w3m: Open pages in external browsers

By default, w3m-previous-buffer is mapped to C-c C-p and w3m-next-buffer is mapped to C-c C-n. On a QWERTY keyboard, you may want to remap w3m-previous-buffer to q and w3m-next-buffer to w. You’ll probably also want to remap w3m-close-window (which had been bound to q), and x is a good keybinding for that. To make all these changes, add the following to your ~/.emacs:

(eval-after-load 'w3m
  '(progn
     (define-key w3m-mode-map "q" 'w3m-previous-buffer)
     (define-key w3m-mode-map "w" 'w3m-next-buffer)
     (define-key w3m-mode-map "x" 'w3m-close-window)))

If you use a Dvorak keyboard layout, you can bind . to w3m-previous-buffer and , to w3m-next-buffer instead. Just add the following code to your ~/.emacs:

(eval-after-load 'w3m
  '(progn
     (define-key w3m-mode-map "." 'w3m-previous-buffer)
     (define-key w3m-mode-map "," 'w3m-next-buffer)))

(This is part of the draft for my book on Emacs, to be published by No Starch Press if I’m not too late.)

Post from: sacha chua :: enterprise 2.0 consultant, storyteller, geek. Check out my blog for tips on managing virtual assistants, Drupal, and other topics!

Emacs and w3m: Making tabbed browsing easier

Here’s my current configuration:

(require 'anything)
(require 'anything-config)
(setq anything-sources
      (list anything-c-source-buffers
            anything-c-source-file-name-history
            anything-c-source-info-pages
            anything-c-source-man-pages
	    anything-c-source-file-cache
            anything-c-source-emacs-commands))
(global-set-key (kbd "M-X") 'anything)

Post from: sacha chua :: enterprise 2.0 consultant, storyteller, geek. Check out my blog for tips on managing virtual assistants, Drupal, and other topics!

Emacs: Jump to anything

Define the function by adding the following code to your ~/.emacs:

(defun wicked/toggle-w3m ()
  "Switch to a w3m buffer or return to the previous buffer."
  (interactive)
  (if (derived-mode-p 'w3m-mode)
      ;; Currently in a w3m buffer
      ;; Bury buffers until you reach a non-w3m one
      (while (derived-mode-p 'w3m-mode)
	(bury-buffer))
    ;; Not in w3m
    ;; Find the first w3m buffer
    (let ((list (buffer-list)))
      (while list
	(if (with-current-buffer (car list)
	      (derived-mode-p 'w3m-mode))
	    (progn
	      (switch-to-buffer (car list))
	      (setq list nil))
	  (setq list (cdr list))))
      (unless (derived-mode-p 'w3m-mode)
	(call-interactively 'w3m)))))

Then bind it to a shortcut key sequence (F7 F7 in this example) by adding the following code to your ~/.emacs:

(global-set-key (kbd " ") 'wicked/toggle-w3m)

You can then use F7 F7 to switch back and forth between your web browser and whatever else you’re working on.

Post from: sacha chua :: enterprise 2.0 consultant, storyteller, geek. Check out my blog for tips on managing virtual assistants, Drupal, and other topics!

Emacs and W3M: Toggling between work and the Web

The following code allows you to set your user agent (wicked/w3m-set-user-agent), reload the current page using a specified user agent (wicked/w3m-reload-this-page-with-user-agent), and define regular expression matches for URLs to control user agent strings (wicked/w3m-fake-user-agent-sites). To use this, add the following to your ~/.emacs:

 (defvar wicked/w3m-fake-user-agents ;; (1)
   `(("w3m" . ,(concat "Emacs-w3m/" emacs-w3m-version " " w3m-version))
     ("ie6" . "Mozilla/4.0 (compatible; MSIE 6.0; Windows NT 5.1)")
     ("ff3" . "Mozilla/5.0 (X11; U; Linux i686; en-US; rv:1.9.0.1) Gecko/2008070206 Firefox/3.0.1")
     ("ff2" . "Mozilla/5.0 (X11; U; Linux i686; en-US; rv:1.8.1.13) Gecko/20080208 Firefox/2.0.0.13")
     ("ie7" . "Mozilla/4.0 (compatible; MSIE 7.0; Windows NT 5.1; .NET CLR 2.0.50727)")
     ("ie5.5" . "Mozilla/4.0 (compatible; MSIE 5.5; Windows 98)")
     ("iphone" . "Mozilla/5.0 (iPhone; U; CPU iPhone OS 2_0 like Mac OS X; en-us) AppleWebKit/525.18.1 (KHTML, like Gecko) Version/3.1.1 Mobile/5A347 Safari/525.20")
     ("safari" . "Mozilla/5.0 (Macintosh; U; Intel Mac OS X 10_5_2; en-us) AppleWebKit/525.13 (KHTML, like Gecko) Version/3.1 Safari/525.13")
     ("google" . "Mozilla/5.0 (compatible; Googlebot/2.1; +http://www.google.com/bot.html)"))
   "*Associative list of user agent names and strings.")

 (defvar wicked/w3m-fake-user-agent-sites ;; (2)
   '(("^https?://www\\.useragentstring\\.com" . "ff2"))
   "*Associative list of regular expressions matching URLs and the agent keyword or value.
 The first matching entry will be used.")

 (defun wicked/w3m-set-user-agent (agent)
   "Set the user agent to AGENT based on `wicked/w3m-fake-user-agents'.
 If AGENT is not defined in `wicked/w3m-fake-user-agents', it is used as the user agent.
 If AGENT is empty, the default w3m user agent will be used."
   (interactive
    (list
     (completing-read "User-agent [w3m]: "
                    (mapcar 'car wicked/w3m-fake-user-agents)
                    nil nil nil nil "w3m"))) ;; (3)
   (if agent
       (progn
        (setq w3m-user-agent
              (or
               (and (string= agent "") (assoc "w3m" wicked/w3m-fake-user-agents)) ;; (4)
               (cdr (assoc agent wicked/w3m-fake-user-agents)) ;; (5)
               agent)) ;; (6)
        (setq w3m-add-user-agent t))
     (setq w3m-add-user-agent nil)))

 (defun wicked/w3m-reload-this-page-with-user-agent (agent)
   "Browse this page using AGENT based on `wicked/w3m-fake-user-agents'.
 If AGENT is not defined in `wicked/w3m-fake-user-agents', it is used as the user agent.
 If AGENT is empty, the default w3m user agent will be used."
   (interactive (list (completing-read "User-agent [w3m]: "
                    (mapcar 'car wicked/w3m-fake-user-agents)
                    nil nil nil nil "w3m")))
   (let ((w3m-user-agent w3m-user-agent)
       (w3m-add-user-agent w3m-add-user-agent))
     (wicked/w3m-set-user-agent agent) ;; (7)
     (w3m-reload-this-page)))

 (defadvice w3m-header-arguments (around wicked activate) ;; (8)
   "Check `wicked/w3m-fake-user-agent-sites' for fake user agent definitions."
   (let ((w3m-user-agent w3m-user-agent)
         (w3m-add-user-agent w3m-add-user-agent)
         (sites wicked/w3m-fake-user-agent-sites))
     (while sites
       (if (string-match (caar sites) (ad-get-arg 1))
         (progn
           (wicked/w3m-set-user-agent (cdar sites))
           (setq sites nil))
       (setq sites (cdr sites))))
     ad-do-it))

wicked/w3m-fake-user-agents sets up a number of common user agents(1) using examples from http://www.useragentstring.com. If you frequently use other user agents, add them to this associative list. wicked/w3m-fake-user-agent-sites sets up some rules for URLs so that you can work around specific websites(2). The first matching rule will be used.

wicked/w3m-set-user-agent can be called from a w3m browser session to set the user agent for all new pages visited. By default, it uses the w3m user agent(3). It will also use the w3m user agent if the agent is blank(4). If the user agent is one of the frequently-used agents defined in wicked/w3m-fake-user-agents, then the corresponding user agent string will be used(5). If not, the string will be used as-is(6). If the agent is nil, the user agent string will be disabled.(7)

You can check a single page using a different user agent by using M-x wicked/w3m-reload-this-page-with-user-agent. It temporarily sets the user agent and then reloads the current page.(7)

The last segment of code modifies the behavior of w3m-header-arguments(8), matching wicked/w3m-fake-user-agents against the URL. This temporarily sets the user agent for matching sites.

Post from: sacha chua :: enterprise 2.0 consultant, storyteller, geek. Check out my blog for tips on managing virtual assistants, Drupal, and other topics!

Emacs and w3m: Fake your user agent

First, set up keywords by adding the following lines to your ~/.emacs. We’ll use an associative list of regular expressions and substitutions, like this:

(setq wicked/quick-search-alist
      '(("^g?:? +\\(.*\\)" . ;; Google Web
         "http://www.google.com/search?q=\\1")

        ("^g!:? +\\(.*\\)" . ;; Google Lucky
         "http://www.google.com/search?btnI=I%27m+Feeling+Lucky&q=\\1")

	("^dict:? +\\(.*\\)" . ;; Dictionary
	 "http://dictionary.reference.com/search?q=\\1")))

This will turn "g keyword1 keyword2" into a Google search for keyword1 and keyword2.

Next, define advice for the functions that open URLs. Before-type advice allows you to modify arguments before the function is run, and we’ll use that to change the URLs. To modify the URL behavior of w3m, add the following to your ~/.emacs:

(require 'cl-seq)
(defadvice w3m-goto-url (before wicked activate)
  "Use the quick searches defined in `wicked/quick-search-alist'."
  (let* ((my-url (replace-regexp-in-string
		  "^ *\\| *$" ""
		  (replace-regexp-in-string "[ \t\n]+" " " (ad-get-arg 0))))
	 (match (assoc-if
		 (lambda (a) (string-match a my-url))
		 wicked/quick-search-alist)))
    (if match
	(ad-set-arg 0 (replace-regexp-in-string
		       (car match) (cdr match) my-url)))))

This sets up your quick searches for use within w3m. To set up quick searches for use with browse-url and external browsers, add the following to your ~/.emacs:

(defadvice browse-url (before wicked activate)
  "Use the quick searches defined in `wicked/quick-search-alist'."
  (let* ((my-url (replace-regexp-in-string
		  "^ *\\| *$" ""
		  (replace-regexp-in-string "[ \t\n]+" " " (ad-get-arg 0))))
	 (match (assoc-if
		 (lambda (a) (string-match a my-url))
		 wicked/quick-search-alist)))
    (if match
	(ad-set-arg 0 (replace-regexp-in-string
		       (car match) (cdr match) my-url)))))

To try out your searches, use M-x browse-url RET g emacs RET to do a Google search for all things Emacs, and use M-x w3m-goto-url (usually bound to g) inside w3m to use the quick searches.

You can define more quick searches like this:

(add-to-list 'wicked/quick-search-alist
          '("^ew:? *?\\(.*\\)" . ;; Emacs Wiki Search
            "http://www.emacswiki.org/cgi-bin/wiki?search=\\1"))

Post from: sacha chua :: enterprise 2.0 consultant, storyteller, geek. Check out my blog for tips on managing virtual assistants, Drupal, and other topics!

Emacs and w3m: Quick searches

1. Enable cookies by setting w3m-use-cookies to t.
2. Go to http://m.facebook.com .
3. Choose the HTTP login.
4. Log in with your username and password.

Hooray for mobile interfaces that don’t require Javascript! =D

So far, it seems to work. I can update my status! Sweet!

Next step: Figure out how to set up shimbun for Facebook mail so that I can read my Facebook mail like a newsgroup…

Post from: sacha chua :: enterprise 2.0 consultant, storyteller, geek. Check out my blog for tips on managing virtual assistants, Drupal, and other topics!

Sweet! Facebook in Emacs!

With Emacs’ reputation for including everything _and_ the kitchen sink, you probably won’t be surprised to hear that there’s more than one way to surf the Internet using your text editor. With today’s Javascript- and image-heavy websites, it can be hard to believe that anyone would use a text-based browser with limited support for many of the things we take for granted. Still, a Web browser in your text editor can be surprisingly useful. Here are some of the reasons why you might like it:

• Browsing is faster and less distracting. Forget flashing ads, garish colors, and large images. When you surf the Web in Emacs, you can focus on reading, and you can use all the typical Emacs shortcuts for navigating around. You can view images when you want to.
  If you need to see something that Emacs doesn’t support, you can easily open the current page in an external Web browser.
• You can integrate it into your work. With a little bit of Emacs Lisp, you can qucikly look up information on the Web based on what you’re currently working on. For example, PHP mode comes with a shortcut that lets you look up the current function’s documentation in the PHP manual. You can look up bug report details, dictionary definitions, and Wikipedia pages with minimal typing, too. If you use Emacspeak, you can set up the web browser to speech-synthesize more than what’s displayed on screen. The more you use Emacs, the more benefits you get from the integration.
• You can customize everything. You can customize your Emacs experience quickly and easily, and if you spend a lot of time on the Net, you’ll appreciate having your own shortcuts and functions. For example, I’ve completely remapped my keyboard shortcuts to support tabbed browsing on a Dvorak keyboard, and I’ve defined a few functions to make frequently-used commands much easier. You can even use functions to process Web pages and either summarize the information you’re interested in or make pages more navigable. It’s all just Emacs Lisp.
• You’re safe from browser exploits. No Javascript pop-ups, no image bugs, no browser-based malware that can take over your comuter or steal data. Just content.
• You need less memory. Why open up a memory-intensive graphical Web-based browser when you’ve got Emacs open anyway?

There’s more than one way to browse the Web in Emacs, of course. Browse-url is a package that makes it easy to open URLs in your preferred browser or browsers. For example, you can use it to browse the Web in Mozilla Firefox, and (of course) you can use it to browse the Web within Emacs itself. For browsing within Emacs, you can use w3m.el, an interface to the external W3M browser, or w3, a Web browser written entirely in Emacs Lisp. Of the two, I prefer w3m.el, which is much faster and more featureful than w3. Both can display graphics, tables, and frames, and w3 supports stylesheets.

More about Emacs and browsing the Web soon! Planned projects for this chapter of Wicked Cool Emacs:

*** Project XXX: Browse the Web
*** Project XXX: Open the current webpage in an external browser
*** Project XXX: Different browsers for different pages
*** Project XXX: Toggle between Web and work
*** Project XXX: Quick search
*** Project XXX: Customize your keymap
*** Project XXX: Download files
*** Project XXX: Add access keys
*** Project XXX: Use social bookmarking
*** Project XXX: Typeahead
*** Project XXX: Preview HTML
*** Project XXX: Read Web pages as news

Post from: sacha chua :: enterprise 2.0 consultant, storyteller, geek. Check out my blog for tips on managing virtual assistants, Drupal, and other topics!

Why browse the Web in Emacs?

I’ve been using yasnippet for my Emacs templates. All I needed to do to automate that little update bit was to write some code that figured out what the next update number should be. Here’s the snippet file I’ve just added (~/elisp/snippets/php-mode/drupal-mode/_update):

function `(sacha/drupal-module-name)`_update_`(sacha/drupal-module-update-number)`() {
  $ret = array();
  $0
  $ret[] = array(
    'success' => true,
    'query' => '$1',
  );
  return $ret;
}

The relevant functions from my ~/.emacs:

(defun sacha/drupal-module-update-number ()
  "Return the number of the next module update function.
This is one more than the highest number used so far.
This function should be called in a module's .install file."
  (save-excursion
    (save-restriction
      (widen)
      (goto-char (point-min))
      (let ((module-name (sacha/drupal-module-name))
	    (max 0))
	(while (re-search-forward
		(concat "function[ \t\n]+" module-name "_update_\\([0-9]+\\)") nil t)
	  (setq max (max (string-to-number (match-string 1)) max)))
	(number-to-string (1+ max))))))

(defun sacha/drupal-module-name ()
  "Return the Drupal module name for .module and .install files."
  (file-name-sans-extension (file-name-nondirectory (buffer-file-name))))

I can’t think of how I’d do that in Eclipse. =) Don’t get me wrong–I still like Eclipse–but I heart being able to hack my editor on the fly.

Post from: sacha chua :: enterprise 2.0 consultant, storyteller, geek. Check out my blog for tips on managing virtual assistants, Drupal, and other topics!

Drupal, Emacs, and templates: Module update functions