October's Emacs Carnival theme "Are keyboards and M-x here to stay?" is a good nudge to think about the voice interface I've been experimenting with and where I want to take it.

Like Chris Maiorana, I love the way Emacs's M-x (execute-extended-command) allows me to call any command by name. It means that I can call commands or come up with my own commands without worrying about assigning them to keyboard shortcuts or making sense of where to place them in a hierarchical menu. With flexible completion via the vertico and orderless packages, I don’t even need to type in the full name of the command or remember the words in the right order. If I still can’t remember the command, it’s easy enough to use defalias to make my own nickname for it.

I tend to limit keyboard shortcuts to only my most common commands. Everything else is hard to practise enough so that it sticks in my muscle memory. Even with marginalia showing me keybindings when I use M-x and which-key showing me hints when I pause, it doesn’t sink in.

Maybe I could use key-quiz to drill a small number of keyboard shortcuts I’m actively working on learning, or modify help-quick-sections to show me reminders when I use C-h C-q (help-quick-toggle).

Getting one keyboard shortcut to do the right thing in different contexts is great because it means fewer shortcuts to memorize. Sometimes I can do that by binding the right functions to different mode maps with bind-key, like the way my sacha-org-insert-link-dwim uses the right link syntax in Markdown or OddMuse too. I also like the context-sensitive keyboard shortcuts I get from Embark. I find myself using a handful of those regularly, and C-. (embark-act) starts a bunch of shortcuts across different types of things: i to insert, w to copy, and so on. For example, I know C-x C-f (find-file) will let me select a file to open. Instead of opening it, I can use C-. i to insert the filename into the buffer.

Simpler keyboard shortcuts help. I rarely use the numpad on my laptop keyboard, so those keys can be mapped to functions that don't need to be followed by lots of typing. For example, 0 is a large button. I use it to start and stop speech recognition. Actually, I bind f9 in Emacs to sacha-whisper-run-at-point, and I bind numpad-0 as a keyboard shortcut in KDE (my window manager) instead of just in Emacs so that it's available globally. I'm still on X11 instead of Wayland. The shell script xdotool-emacs focuses Emacs briefly and sends the keys, and the shortcut is set to /home/sacha/bin/xdotool-emacs key --clearmodifiers F9. I do that instead of using emacsclient because emacsclient starts a different buffer, and I might want to keep the context. My sacha-whisper-maybe-type function detects if Emacs is not the focused application and types the text if it isn't, which means I can use it as keyboard input for oher applications while still taking advantage of the corrections and commands I've defined in Emacs. An easy-to-press global shortcut means I can use it from anywhere, even when my foreground app is the browser or another application.

An additional modifier opens up more possibilities for keyboard shortcuts near the regular typing position. My Windows key acts like a Super modifier. I've set it up as a one-shot modifier with Kanata so that I can either hold it down to access more shortcuts or tap it to treat it like a leader key.

There are quite a few commands for which neither M-x nor keyboard shortcuts feel like the right fit: things I want to do faster or more fluidly than M-x, but which I don't do often enough to memorize a good shortcut for. I've been experimenting a bit with voice input, and I really like it.

• I could use more practice speaking, since I don't talk to a lot of people in real life.
  • English: Videos and livestreams can be a way to share interesting things and start conversations. I want to organize my thoughts, improve my breathing, and reduce my stutters and false starts. That will make the audio more pleasant to listen to. Dictating to my computer gives me more practice. It also makes things easier to livestream if I can reuse my speech as input.

  • French: I like challenging my brain and I want to help the kiddo learn it too. Improving my speaking will also make it easier for me to listen to myself and close the feedback loop. Maybe I can even use speech recognition to give me feedback and increase motivation while speaking, like keeping track of words or phrases I want to use. When I use them in conversation, the buffer can cross them off the list, which lets me focus on the words remaining.

    

• Dictation can capture ideas quickly, with more natural wording, especially since typing sometimes gets messed up on my computer.
• Voice interfaces might let me reduce some kinds of task friction or work hands-free. For example, I like setting timers by voice on my phone while cooking. It might be interesting to be able to dictate a draft while knitting or hand-sewing.
• Brain fog is something I will likely need to deal with. I got a preview of it thanks to the sleep deprivation of early parenting. I know that brain fog is probably going to happen around menopause, it will probably also be part of aging, and it's a common symptom of long COVID which I might still end up getting despite my precautions. I could get into an accident and hurt my hands. I like Emacs and I want to be able to keep using it even if cognitive or physical changes make it harder to remember or use lots of keyboard shortcuts. If I start playing around with this now, the capabilities and the habits will be there when I need it.
• Other people are already dealing with those kinds of physical or cognitive constraints, so things I figure out might be useful for other people.
• A global shortcut for voice notes and commands let me quickly dash off a reminder before I take off. I don't have to find Emacs and go through my Org capture templates.
• It's fun. I like saying "Prepare for take-off" and having Emacs get ready for a spontaneous stream by updating YouTube using my current Org Mode subtree title and description. I like seeing if my dictionary of substitutions can fix the commonly misrecognized words. Saying "I command you to…" to get Emacs to do a M-x command is totally inefficient but also playful, and silly things stick in my brain better thanks to the mnemonic advantage of humor. My brain likes that kind of novelty.

For context, I use Linux on a Lenovo P52 laptop (manufactured 2018, 64 GB RAM but hardly any GPU), and I have an Android phone. I like writing regular text, Emacs Lisp, and some Python and JavaScript. I'm slowly starting to have more focused time now that the kiddo is in virtual school, although it's still broken up by recess and lunch. I will probably have an increasing amount of focused time over the next few years.

I love the way voice reduces context shifts. For example, some of my most-used voice commands are:

• remind me [today/tomorrow/next week/next month/someday] to…: capture and schedule the task; include an Org link and screenshot for context, and link to the audio recording in case the text was misrecognized
• switch to…: capture the task and immediately clock into it
• where was I?: jump to the current task
• what was I doing?: list recently-clocked tasks

I don't have to think about which keys I've configured in org-capture-templates. I just use a natural phrase.

I've defined "open …" to open things from my bookmarked links stored in an Org file. Because my numpad-0 keybinding works from anywhere, I can even use it to open sites or capture notes while looking at my browser.

Because Emacs can interact with lots of other applications, I can even experiment with controlling those applications by voice. For example, I use obs-websocket.el to control OBS for streaming or recording a video. Using "Let's go live" and "Over and out" to start or stop streaming or "Start recording" and "Stop recording" to manage the recording means I can do that without needing to find the right window. I stream with a 10-second delay so that there's a little bit of time to catch any private information that's been accidentally shared on the screen. My new "panic" command lets me discard that delay and interrupt the stream by using an OBS keyboard shortcut to kill the stream immediately, even if I'm probably not going to remember that exact keyboard shortcut when I'm stressed. It should be a little easier to remember that than a keyboard shortcut I hardly ever use or a menu item that is a really small target (and my Emacs might not even be my foreground app).

For regular dictation, I'm experimenting with having it automatically place each sentence on a new line or list item. This makes it easy to reorganize in Org. I can refill it into a paragraph when I'm done.

I still have to deal with the limits of my memory, of course. I have a "what can I say" command that opens up an Org file with my notes. I keep this as a manual note instead of just dumping the contents of my sacha-whisper-commands variable so that I can prioritize the things I'm trying to build as habits.

Here's the part of my config that sets up some speech commands.

I might want more complex grammar someday for things that regular expressions can't easily handle. That's something other projects have done a good job of figuring out.

There's been a lot of good work on voice input over the years, especially since a number of Emacs users have a hard time with or would like to avoid repetitive stress injury. In addition to the innumerable projects that let you use Whisper or similar speech recognition engines to dictate prose, there are also a few projects that use a constrained vocabulary to more reliably control Emacs. Two projects in this area are based on the Talon voice control system: Voicemacs and Emacslisten.

• The Talon community hub defines some Emacs commands. I think it simulates keyboard input and assumes that you have flx or some other fuzzy completion matching so that input like M-x t-d-on-e runs toggle-debug-on-error, as defined in community/apps/emacs/emacs_commands.csv. I seem to be having a hard time with getting orderless to do that with orderless-flex, so I'm just going to remove that column of the CSV from my emacs_commands.csv.
• Emacslisten uses Emacs Lisp macros to define the command vocabulary. Cursorfree defines a whole bunch of them, using hatty for voice navigation within a buffer.
• Voicemacs defines its commands in Python in the user's Talon config (see example). It feels fairly complex, like it assumes it's being cloned as your ~/.talon/user directory. It lets Emacs and Talon communicate via RPC to send additional context. It also extends some things like dired and company to make them more voice-friendly.

I'm new to both projects, so I'm not sure if I'm reading this right, but I think I might be able to use Emacslisten to define voice commands with Emacs Lisp, and then maybe someday use Voicemacs to provide richer context for some of those commands. For example, Voicemacs can list snippets, but I'm not quite sure how to use that yet.

It looks like I can use Talon for commands and my whisper.el setup for regular dictation at the same time. The Pipewire virtual sinks help with that, I think, since the programs don't have to have an exclusive lock on the audio device. This means that I can explore the kinds of vocabularies that people have set up while also taking advantage of greater accuracy and ease of correction in my whisper dictation workflow. I think I can use the Talon process socket to turn off recognition when I want to dictate using my whisper.el setup, and then I can turn it back on afterwards.

A note about the underlying speech recognition: Talon is cross-platform and free, but not open source. Subscribing to Talon (CAD 36/month) lets you use a Conformer + Whisper hybrid engine that uses whisper-large for more accuracy, but that's a bit on the expensive side for me. Dragonfly is a free open source engine that can use Kaldi or CMU Pocket Sphinx for speech recognition, but I'm not sure what the performance is like.

Interestingly, because Talon simulates keystrokes, using the commands from the community set means keys sometimes arrive out of order on my computer. "split solo" is supposed to run M-x delete-other-windows, but it sometimes ends up sending M-x delete-other-wnidows instead. This is the same sort of annoyance that gets in the way of typing quickly on my computer. Keystrokes get processed out of order when the CPU gets busy, which is part of the reason why I find dictation to be more reliable than typing sometimes. I should fix that someday, but my attempts so far aren't working. (I wonder if it has something to do with the GPU under Linux; maybe I should drop back down to CPU only since it turns out I can't use the GPU for much anyway.) Quick fix, let's try adding a brief delay in my settings.talon:

settings():
    # Adds a small pause (in ms) between each character typed
    insert_wait = 5

    # Ensures modifiers (Shift/Ctrl) don't un-latch too fast
    key_wait = 1.0

I think Voicemacs uses a sevver and and Emacslisten uses emacsclient to communicate with Emacs directly, so they probably won't run into this keystroke problem.

It might be interesting to see if I can port some of my simpler commands over to Emacslisten or straight Talon so that they're always active. Then I can slowly work on getting used to the other commands people find useful, or incorporating them into my setup.

I love shifting fluidly from one form of input to another, depending on what makes sense at that moment.

For example, I often start my thoughts by drawing on a light dotted grid using Noteful on my iPad. That lets me quickly cluster ideas spatially, drawing connections and highlighting words as I figure out what I want to say.

Then I use dictation and typing to sketch the outline, jumping around as thoughts occur to me. If I'm livestreaming at the same time, that helps me demonstrate things along the way and lets me benefit from people's questions. Dictation lets me explain things to people and capture the text at the same time.

I can move around with the keyboard, but it would be really cool to use voice for quick navigation between sections of my outline using either line numbers or words. I've implemented a "line" command that lets me jump to a line using the last two digits of its line number, since I probably won't have more than 100 lines visible on the screen at a time. For example, this line is currently 119, so referring to it as "nineteen" would work. I'd like to add more operations for editing the text. I think it would be great to be able to say "kill line 33" to delete that line or "move lines 16 to 20 after 27" to have it move those lines there.

I now have a sacha-whisper-one-sentence-per-line variable that splits up dictation if non-nil, so we'll see where those take me. Orukeet does a reasonable job of punctuating my sentences if I don't pause too much between phrases. My M-q re-wraps paragraphs between one sentence per line, one paragraph per line, and wrapping to fill-column, and it's probably the sort of thing that more voice commands would make even more convenient.

Maybe I can even use that spatial sense of a layout by touching buttons in an Emacs-served webpage on my tablet to direct my dictation to different places. Org-draw uses a similar Emacs web server approach to let you draw on another device and embed the results into an Org file, and there are also simpler HTTP servers (web-server, simple-httpd), so it's probably quite doable. I'm imagining something that takes the top-level items from my current nested list and makes them nice big buttons, so I could have something like "Introduction", "Keyboard", "Reasons", "Experiment", "Hybrid", and "Conclusion", and clicking on those could trigger a POST request to the server inside Emacs which moves my point accordingly. I might even have buttons for various commands. It sounds pretty straightforward to implement.

When my brain comes up with lots of interesting ideas, my org-capture voice commands let me choose which rabbit holes to postpone and which ones I want to dive into.

If I get interrupted by life, I can write on my phone while waiting for the kiddo. Orgzly Revived and Syncthing let me pick up where I left off.

As I get thoughts down, I can use keyboard shortcuts to rearrange things and then convert the list of sentences into paragraphs. I can easily turn text into links using my favourites.

I can imagine combining the audio clips from the text properties with the videos and screenshots to create a quick narrated clip that I can edit (using Emacs, of course), or publishing the narration so that people can listen to it if they like.

This combination of drawing + audio + text works better for me than any of those components alone. Visuals give me anchors for my thoughts. Audio helps with the braindump. Text permits precise, searchable details we can copy. Like George Jones, I find they all have their uses and their strengths.

When I try to dictate longer sections without that kind of visual support, I often lose my train of thought. I want to see where I've been and where I want to go. I don't trust LLMs to clean up that kind of rough transcript; the output doesn't quite resonate with me. I like keeping speech recognition constrained to sentences I can immediately check or reorganize, and I have the recordings as text properties so I can go back to that segment if I need to (at least during the current editing section). That way, I'm never left scratching my head and wondering what I meant.

I love that local speech recognition is getting better and better. I'm curious about whether small language models can do better turn detection to help compensate for my intra-phrase delays when I'm thinking of a word, and whether decision models can automatically classify a sentence into its place in my outline. I think it would be cool if embeddings or other language models could suggest related words or resources as I go along. Lots of interesting possibilities even with the technology that's already available.

Thanks to George Jones for hosting this month's Emacs Carnival on input alternatives. Check out the page for more posts!

This code uses this server vad-file.py, which I generated with Google Gemini. It emits JSONL for voice activity detection events (start/stop) and uses Orukeet to transcribe the speech once the voice activity detection notices it's finished. I also use spacy to look up token information because I want to someday colour the nouns by gender, which might allow me to correct myself in the next sentence instead of hesitating in the previous one.

;; Report on the balance between my tutor and me
(defvar sacha-vad-tutor-process nil)
(defvar sacha-vad-tutor-dir "~/vendor/orukeet")
(defvar sacha-vad-tutor-command `(,(expand-file-name ".venv/bin/python" sacha-vad-tutor-dir)
                                  "asr.py"
                                  "--spacy-model"
                                  "fr_dep_news_trf"
                                  "-s" "300" "-t"
                                  "VirtualMicSink.monitor=sacha" "alsa_output.usb-AT_AT2040USB_202011110001-00.analog-stereo.monitor=tutor"))
(defvar sacha-vad-tutor-events nil "List of events as an list of alists (label start stop duration).")
(defvar sacha-vad-tutor-labels '("sacha" "tutor"))
(defvar sacha-vad-tutor-summary '(("sacha" . 0)
                                  ("tutor" . 0)))
(defvar sacha-vad-tutor-session-length (* 60 60) "Number of seconds to use for scale.")

(defun sacha-vad-tutor-update-view ()
  "Visualize the last 3 minutes and the overview of the session.
Also keep track of target phrases."
  (interactive)
  (with-current-buffer (get-buffer-create "*tutor stats*")
    (erase-buffer)
    (let* ((total (apply '+ (mapcar 'cdr sacha-vad-tutor-summary)))
           (height 30)
           (width (window-width nil t))
           (max-seconds
            (if sacha-vad-tutor-events
                (apply 'max (mapcar (lambda (o) (alist-get 'end o))
                                    sacha-vad-tutor-events))
              0))
           (threshold 180)              ; last three minutes
           (threshold-seconds (- max-seconds threshold))
           (recent
            (seq-keep
             (lambda (o)
               (when (>= (alist-get 'start o)
                         threshold-seconds)
                 (let-alist o
                   `((label . ,.label)
                     (start . ,(- .start threshold-seconds))
                     (end . ,(- .end threshold-seconds))))))
             (copy-sequence sacha-vad-tutor-events)))
           (recent-total (apply '+ (mapcar (lambda (o)
                                             (-
                                              (alist-get 'end o)
                                              (alist-get 'start o)))
                                           recent))))
      (save-excursion
        (insert
         (format "Last %d minute%s:\n"
                 (/ threshold 60)
                 (if (> (/ threshold 60) 1)
                     "s"
                   ""))
         (mapconcat
          (lambda (o)
            (format "%d%% %s\n"
                    (/ (* 100.0 (cdr o)) recent-total)
                    (car o)))
          (seq-map
           (lambda (group)
             (cons (car group)
                   (apply '+ (mapcar (lambda (o)
                                       (-
                                        (alist-get 'end o)
                                        (alist-get 'start o)))
                                     (cdr group)))))
           (seq-group-by (lambda (o) (alist-get 'label o)) recent)))
         "\n")
        (svg-insert-image
         (sacha-vad-visualize
          sacha-vad-tutor-labels
          recent
          t
          width height))
        (insert
         "\nTotal:\n"

         (mapconcat
          (lambda (o)
            (format "%d%% %s\n"
                    (/ (* 100.0 (cdr o)) total)
                    (car o)))
          sacha-vad-tutor-summary))
        (svg-insert-image
         (sacha-vad-visualize sacha-vad-tutor-labels sacha-vad-tutor-events t
                              width height
                              sacha-vad-tutor-session-length))
        (insert "\n\n"  (sacha-learn-lang-bingo-summary))))))

(defun sacha-vad-handle-end-event (data)
  "Handle the end event."
  (let ((event (list
                (cons 'label (alist-get 'label data))
                (cons 'start (- (alist-get 'timestamp data)
                                (alist-get 'duration data)
                                (or sacha-vad-tutor-start-seconds 0)))
                (cons 'end (- (alist-get 'timestamp data)
                              (or sacha-vad-tutor-start-seconds 0))))))
    (push event sacha-vad-tutor-events)
    (let-alist data
      (incf (alist-get (alist-get 'label data) sacha-vad-tutor-summary 0 nil 'string=)
            .duration))
    (sacha-vad-tutor-update-view)))

(defun sacha-vad-tutor-filter (proc string)
  "Add and parse."
  (when (buffer-live-p (process-buffer proc))
    ;; split the string by newline?
    (with-current-buffer (process-buffer proc)
      (goto-char (point-max))
      (save-excursion
        (insert string))
      (catch 'waiting
        (unless (or (eobp) (looking-at "\n*$"))
          (let ((data (json-read)))
            (when (string= (alist-get 'event data) "end")
              (sacha-vad-handle-end-event data))
            (when (string= (alist-get 'event data) "final")
              (sacha-vad-handle-text-event data))))))))

(defvar sacha-vad-last-speaker nil "Previous speaker.")

(defun sacha-vad-handle-text-event (data)
  (with-current-buffer (get-buffer-create "*Transcript*")
    (set (make-local-variable 'window-point-insertion-type) t)
    (save-excursion
      (goto-char (point-max))
      ;; insert break
      (insert
       (if (string= sacha-vad-last-speaker (alist-get 'label data))
           " "
         (concat (if (bobp) "" "\n\n") (alist-get 'label data) ": "))
       (alist-get 'text data))
      (setq sacha-vad-last-speaker (alist-get 'label data))
      (when (string= (alist-get 'label data) "sacha")
        (sacha-learn-lang-notice-bingo-words (alist-get 'text data))))))

(defun sacha-vad-tutor-start ()
  "Start the process."
  (interactive)
  (sacha-vad-tutor-ensure)
  (setq sacha-vad-tutor-summary '(("sacha" . 0)
                                  ("tutor" . 0))
        sacha-vad-tutor-events nil)
  (with-current-buffer (get-buffer-create "*Transcript*")
    (erase-buffer)
    (display-buffer (current-buffer)))
  (display-buffer (get-buffer-create "*tutor stats*")))

(defun sacha-vad-tutor-ensure ()
  "Start the process if it's not already running."
  (interactive)
  (unless (process-live-p sacha-vad-tutor-process)
    (setq sacha-vad-tutor-process-start-time (current-time))
    (setq sacha-vad-tutor-start-seconds 0)
    (let ((default-directory sacha-vad-tutor-dir))
      (setq sacha-vad-tutor-process
            (make-process
             :name "vad-tutor"
             :command sacha-vad-tutor-command
             :connection-type 'pipe
             :buffer (get-buffer-create "*vad-tutor*")
             :stderr (get-buffer-create "*vad-tutor-err*")
             :filter #'sacha-vad-tutor-filter)))))

(defun sacha-vad-tutor-stop ()
  "Stop the process."
  (interactive)
  (interrupt-process sacha-vad-tutor-process))

;;;###autoload
(defun sacha-js-parse-jsonl-file (file)
  "Parse jsonl as a list"
  (let (results)
    (with-temp-buffer
      (insert-file-contents file)
      (goto-char (point-min))
      (while (not (eobp))
        (condition-case nil
            (push (json-read) results)
          (error (goto-char (point-max))))))
    (nreverse results)))

(defvar sacha-vad-tutor-start-seconds 0 "Number of seconds to consider as the start.")
(defvar sacha-vad-tutor-process-start-time nil "Time that the process started.")

;;;###autoload
(defun sacha-vad-tutor-reset-clock ()
  "Reset the start of the session."
  (interactive)
  (setq sacha-vad-tutor-start-seconds
        (time-to-seconds (time-subtract (current-time)
                                        sacha-vad-tutor-process-start-time)))
  (mapcar (lambda (o) (setcdr o 0)) sacha-vad-tutor-summary)
  (setq sacha-vad-tutor-events nil))

(defun sacha-vad-visualize (labels list &optional output-file width height max-seconds)
  (setq height (or height 25))
  (setq width (or width (window-width nil t)))
  (let* ((svg (svg-create width height))
         (max-seconds (max
                       (or max-seconds 0)
                       (if list
                           (apply 'max (mapcar (lambda (o) (alist-get 'end o))
                                               list))
                         0)))
         (pixels-per-second (/ (* 1.0 width) max-seconds))
         (row-height (/ height (length labels))))
    (dolist (o list)
      (let-alist o
        (let ((y (* row-height (or (seq-position labels .label 'string=) -1))))
          (when (>= y 0)
            (svg-rectangle
             svg
             (* .start pixels-per-second)
             y
             (* (- .end .start) pixels-per-second)
             row-height :fill "green")))))
    (cond
     ((stringp output-file)
      (with-temp-file output-file
        (svg-print svg)))
     (output-file
      svg)
     (t
      (with-current-buffer (get-buffer-create "*vad*")
        (goto-char (point-min))
        (display-buffer (current-buffer))
        (erase-buffer)
        (svg-insert-image svg))))))

(defun sacha-vad-stats (labels list)
  "Return the balance of time talking as (label total percentage)."
  (let* ((max-seconds (apply '+ (mapcar
                                 (lambda (o) (let-alist o (- .end .start)))
                                 list)))
         (durations (mapcar (lambda (o)
                            (cons
                             (car o)
                             (mapcar (lambda (e) (let-alist e (- .end .start)))
                                     (cdr o))))
                          (seq-group-by (lambda (o) (alist-get 'label o))
                                        list))))
    (seq-map
     (lambda (label)
       (let* ((row (cdr (assoc label durations)))
              (total (apply '+ row)))
         `((label . ,label)
           (total . ,total)
           (count . ,(length row))
           (percentage . ,(and total max-seconds (> max-seconds 0) (* 100.0 (/ total max-seconds)))))))
     labels)))

;; (sacha-vad-stats '("sacha" "tutor") (seq-take (sacha-js-parse-jsonl-file "~/proj/speech/output2.log") 5))
;; (sacha-vad-stats '("sacha" "tutor") (sacha-js-parse-jsonl-file "~/proj/speech/output.log"))
;; (sacha-vad-visualize '("sacha" "tutor") (sacha-js-parse-jsonl-file "~/proj/speech/output.log"))
;; (sacha-vad-visualize '("sacha" "tutor") (seq-take (sacha-js-parse-jsonl-file "~/proj/speech/output2.log") 30))

(defun sacha-vad-tutor-group-output (files)
  (let ((grouped-files (seq-group-by
                        (lambda (o)
                          (substring (file-name-base o) 0 10))
                        files)))
    (mapcar
     (lambda (group)
       (let ((start 0))
         (cons (car (cdr group))
               (seq-reduce
                (lambda (prev file)
                  (append prev
                          (let ((max-seconds 0))
                            (prog1 (mapcar (lambda (event)
                                             (incf (alist-get 'start event) start)
                                             (incf (alist-get 'end event) start)
                                             (setq max-seconds (max (alist-get 'end event) max-seconds))
                                             event)
                                           (sacha-js-parse-jsonl-file file))
                              (setq start max-seconds)))))
                (cdr group)
                nil))))
     grouped-files)))

(defun sacha-vad-tutor-make-table (files &optional width height)
  "Make a summary table."
  (let ((labels sacha-vad-tutor-labels)
        (width (or width 500))
        (height (or height 30)))
    ;; combine data as needed
    (append
     '(("Date" "Tutor" "Minutes" "%" "Visualization") hline)
     (seq-map
      (lambda (group)
        (let* ((list (cdr group))
               (base (file-name-base (car group))))
          (if list
              (let-alist (car (sacha-vad-stats labels list))
                (let ((svg-name
                       (expand-file-name
                        (concat (file-name-base (car group)) "-" .label ".svg")
                        "~/proj/french/conversation")))
                  (sacha-vad-visualize
                   (list .label)
                   list
                   svg-name
                   width
                   height)
                  (list
                   (format-time-string "%Y-%m-%d"
                                       (seconds-to-time
                                        (sacha-filename-timestamp (car group))))
                   ;; (org-link-make-string (concat "file:" o) "file")
                   (if (string-match "-conversation-\\([^\\.]+\\)" base)
                       (s-capitalize (substring (match-string 1 base) 0 1))
                     "")

                   (round (/ .total 60))
                   (format "%d%%" .percentage)
                   (org-link-make-string (concat "file:" svg-name)
                                         (concat "file:" svg-name))
                   )))
            (list "?"))))
      (sacha-vad-tutor-group-output files))
     nil)))

Here's the code that reminds me to use the words or expressions on my to-do list, and then keeps track of how often I've used them, prioritizes the ones that I haven't used yet, and displays these. It can work with either my Whisper dictation workflow or the VAD events server described above.

I keep the list of expressions in file:///home/sacha/proj/french/bingo.txt.

(defvar sacha-learn-lang-bingo-word-file "~/proj/french/bingo.txt")
(defvar sacha-learn-lang-bingo-words nil "List of words.")
(defvar sacha-learn-lang-bingo-words-hash nil "Data for the counts.")

;;;###autoload
(defun sacha-learn-lang-bingo-words ()
  "Load the list of words from the file."
  (interactive)
  (setq sacha-learn-lang-bingo-words
        (seq-map (lambda (o)
                   (when (= (length o) 1)
                     (setq o (list (car o) 0)))
                   (setq o (append o (list
                                      (string-trim (replace-regexp-in-string
                                                    " *\\[.+?\\] *" " "
                                                    (car o))))))
                   o)
                 (pcsv-parse-file sacha-learn-lang-bingo-word-file)))
  sacha-learn-lang-bingo-words)

;;;###autoload
(defun sacha-learn-lang-bingo-handler (event)
  "Manually register the event."
  (interactive "e")
    (let* ((pos (posn-point (event-end event)))
           (val (get-text-property pos 'bingo)))
      (when val
        (sacha-learn-lang-notice-bingo-words val))))

(defvar-keymap sacha-learn-lang-bingo-map
  "<mouse-1>" #'sacha-learn-lang-bingo-handler)

;;;###autoload
(defun sacha-learn-lang-bingo-summary ()
  "Summarize the words to say."
  (let ((target (seq-filter (lambda (row) (= (elt row 1) 0))
                            sacha-learn-lang-bingo-words))
        (yay (seq-filter (lambda (row) (> (elt row 1) 0))
                         sacha-learn-lang-bingo-words)))
    (concat
     (if target
         (concat "Target: "
                 (mapconcat (lambda (row)
                              (propertize
                               (car row)
                               'keymap sacha-learn-lang-bingo-map
                               'bingo (car row)))
                            target
                            "; ")
                 "\n\n")
       "")
     (if yay
         (concat
          "Yay! "
          (mapconcat (lambda (row)
                       (propertize (format "%s (%s)" (car row) (elt row 1))
                                   'keymap sacha-learn-lang-bingo-map
                                   'bingo (car row)))
                     (seq-filter (lambda (row) (> (elt row 1) 0))
                                 sacha-learn-lang-bingo-words)
                     "; ")
          "\n\n")
       ""))))

;;;###autoload
(defun sacha-learn-lang-notice-bingo-words (text)
  "Look for the bingo words in TEXT and celebrate when I use them.
Add to `whisper-insert-text-at-point'."
  (when text
    (unless sacha-learn-lang-bingo-words (sacha-learn-lang-bingo-words))
    (let ((found (seq-find
                  (lambda (o)
                    (and (elt o 2)
                         (string-match (concat "\\<" (elt o 2)) text)))
                  sacha-learn-lang-bingo-words)))
      (when found
        (incf (elt found 1))
        (sacha-vad-tutor-update-view)
        (with-current-buffer (get-buffer-create "*Bingo*")
          (erase-buffer)
          (insert (sacha-learn-lang-bingo-summary))))))
  text)

• 0:00 Opening
• 1:24 Setting things up
• 2:33 Local variables
• 3:56 Mini export menu
• 4:17 Basic output with different fonts
• 4:49 Adding a code block as source
• 6:18 The problem with exporting Unicode
• 7:45 Trying a different font
• 9:05 LuaLaTeX
• 10:37 Switching to FreeSerif, FreeSans, and FreeMono
• 12:04 LuaLaTeX is slower
• 12:42 The fonts are rendered
• 13:42 The farmer on the donkey in front of the train
• 15:35 Unicode and LuaLaTeX
• 17:00 Emojis
• 18:37 Fallback fonts
• 21:39 Fallback configuration
• 22:47 Selecting fonts
• 24:10 Fallbacks
• 26:46 The LaTeX produced
• 27:21 Character families should be in the Messages buffer
• 30:09 Behind the scenes
• 31:00 Refreshing local variables
• 33:37 Scaling fonts to match lowercase
• 34:17 Specifying the fallbacks
• 35:33 HarfBuzz
• 36:17 Upcoming work on Babel (the LaTeX package)
• 37:02 More about HarfBuzz and ligatures?
• 39:23 Upcoming talk on accessible presentations
• 41:19 Upcoming work on Polyglossia and Babel
• 42:02 Chinese, Japanese, and Korean
• 44:22 The development process
• 48:12 Retirement
• 49:41 Fallback fonts
• 53:06 LaTeX versions
• 56:38 Sans serif fonts are better for accessibility
• 57:09 Wanting markup for sans serif
• 1:00:33 Contacting Pedro

J'ai emmené ma fille au cours de gymnastique.

J'ai travaillé sur l'organisation de la conférence.

J'ai essayé mon nouveau microphone AT2040USB. Il est meilleur que le précédent (un Blue Yeti) parce qu'il réduit le bruit.

J'ai mis à jour notre instance de BigBlueButton pour la conférence.

Mon mari et moi avons parlé de la paperasse du régime de retraite et de TFSA.

Mon mari, ma fille et moi sommes allés au cours d'entraînement.

Il y avait une remplaçante ce matin, donc ma fille était un peu en retard parce qu'elle a raté l'annonce d'un autre lien pour la salle de réunion virtuelle.

J'ai travaillé comme consultante ce matin. J'étais heureuse d'aider mon client avec des préparatifs pour un événement en octobre.

J'ai emmené ma fille chez l'hygiéniste pour son nettoyage dentaire. L'hygiéniste est sa tante, donc ma fille est plus à l'aise avec elle qu'avec la précédente.

On s'est régalés ! J'ai préparé des petits pains chinois parce que mon mari a acheté du porc. C'était délicieux. J'ai eu très faim car la recette a pris beaucoup de temps.

Dans notre monde de Minecraft, nous sommes allés au Nether.

J'ai encore oublié de brosser les dents de ma fille ce matin.

J'ai travaillé comme consultante pendant la récré de ma fille, donc elle a oublié de retourner en classe. Oups.

J'ai ajouté quelques soumissions au programme d'EmacsConf. Mais parce que le serveur subit du trafic indésirable, je n'ai pas pu accepter les autres soumissions. J'ai transféré le serveur de la réunion virtuelle à notre compte pour contribuer au quota de trafic réseau.

J'ai envoyé un message au nouveau tuteur. Si j'ai du temps ce soir, je voudrais essayer Praat pour analyser mes voyelles. Donc si je veux le comprendre, je peux poser des questions à mon tuteur demain parce que mon tuteur a beaucoup d'expérience en linguistique et il pourra m'aider.

J'ai enfin analysé mes voyelles avec Praat. J'ai utilisé l'IA pour m'aider à les visualiser.

J'ai eu une séance de conversation avec mon tuteur. Il m'a dit que mon accent est assez facile à comprendre, et nous avons échangé beaucoup d'idées sur la technologie, sur l'apprentissage du français, sur les réseaux informatiques et d'autres sujets. C'était un plaisir. J'ai hâte de parler avec lui la semaine prochaine.

Ma fille était en retard à l'école en ligne.

J'ai emmené ma fille au cours de gymnastique. Au club de gym, il y avait un manteau qui ressemble au manteau de ma fille. Ma fille était absolument certaine qu'elle n'avait pas porté de manteau au gymnase. J'ai demandé à tous les parents au club de gym si quelqu'un connaît le manteau. Personne ne le connaissait. Ma fille a refusé de prendre le manteau sans être sûre, donc nous sommes rentrées à la maison pour chercher notre manteau. Après ne pas l'avoir trouvé, nous sommes retournées au club de gym pour chercher le manteau. Bon, je crois que c'est le sien grâce à des taches de peinture. Il a la même taille et la même marque.

Ma fille était trop fatiguée pour participer à une sortie à vélo, donc nous sommes restées à la maison pendant que mon mari allait à l'événement.

J'ai travaillé comme consultante ce matin, même pendant la récré de ma fille. Du coup, elle a oublié de retourner en classe.

J'ai envoyé le courriel test du bulletin d'information Bike Brigade. Si j'ai le temps et l'énergie, je voudrais travailler sur l'utilisation de la reconnaissance vocale pour commencer et arrêter une diffusion en direct ou un enregistrement, puis explorer le logiciel pour visualiser l'activité vocale sur Emacs. Je voudrais le présenter au tuteur mardi.

Il est possible que j'accomplisse plus si je me concentre sur une chose (même les parties ennuyeuses), mais en ce moment, rien ne me presse et je m'amuse en suivant mes intérêts changeants. Par exemple, sur la reconnaissance vocale, si j'investis le temps de transformer mon code en paquet, d'autres gens peuvent l'essayer et nous pouvons l'améliorer ensemble. Mais c'est si tentant d'explorer de nouveau d'autres idées, particulièrement parce que je sais bien que c'est absolument possible que personne n'utilise ce paquet hypothétique. C'est quand même une bonne occasion de m'entraîner à bricoler en public. Je pourrais faire une diffusion en direct dans laquelle je montrerais la fonctionnalité de ma configuration, puis extraire le code vers le paquet speech-input. La capacité de saisir des tâches à la voix est notamment utile. Je voudrais aussi montrer comment l'utiliser pour les processus qui nécessitent autrement des basculements entre des buffers ou des fenêtres, ce que je n'aime pas parce que je perds souvent le fil de mes pensées.

J'ai failli rater notre station d'échange, mais je m'en suis rendu compte juste à temps.

J'ai implémenté des commandes pour commencer et arrêter une diffusion en direct ou un enregistrement par voix. J'ai aussi implémenté "scratch that" et "I command you to…" qui utilisent unread-command-events pour simuler la saisie.

J'ai rincé le riz que ma fille a mesuré. C'était une grave erreur. Elle voulait le rincer elle-même. Elle est partie furieuse et elle s'est barricadée dans sa chambre.

J'ai organisé mes pensées avant ma conversation de jeudi avec mon tuteur.

J'ai implémenté la visualisation de l'équilibre de la conversation à partir des flux audio ou d'un enregistrement qui comporte des pistes séparées par locuteur.

J'ai essayé quelques modèles de reconnaissance vocale, mais je pense que je n'ai pas encore configuré mon logiciel correctement. Mon taux d'erreur est trop haut.

J'ai ajouté quelques commandes vocales à ma configuration, comme une commande pour saisir la dernière minute dans une autre vidéo.

Ma fille a préparé du curry japonais avec un peu d'aide de mon mari.

Ma fille n'a pas voulu se réveiller à l'heure de la classe. Je l'ai laissée parce que c'est inutile de l'harceler. Si je mets la pression sans motivation de son côté, elle va perdre la journée entière dans sa mauvaise humeur. Si je la laisse parce que c'est son expérience, nous pouvons voir si c'est supportable et nous pouvons utiliser le reste de la journée pour apprendre quelque chose et pour faire les devoirs.

J'ai corrigé un autre bogue dans mon logiciel pour rassembler tous les articles pour Planet Emacslife. C'était encore le problème entre les dates publiées et les dates modifiées.

Ma fille m'a aidée à préparer du bulgogi pour mon ami pendant la pause déjeuner. Après son cours de gymnastique, je le lui ai apporté.

J'ai eu une séance de prononciation. En fait c'était une séance de conversation, mais j'étais confuse et je n'avais pas préparé, donc mon tuteur m'a donné des virelangues. J'ai traité l'enregistrement pendant que ma fille se barricadait dans sa chambre.

Ma fille était inconsolable parce qu'elle a momentanément perdu la bande qu'elle avait dessinée pour la carte d'anniversaire de son amie. Même si mon mari l'a trouvée, elle s'est assise contre sa porte et elle a séché les cours l'après-midi. Bon, je ne peux rien faire de plus dans cette situation sauf attendre jusqu'à ce qu'elle soit calme.

J'ai participé à la réunion virtuelle d'Emacs Paris. C'était une bonne occasion de suivre en auditeur libre et enfin de rencontrer Thierry Stoehr.

Ma fille et moi sommes allées à l'aire de jeux toutes seules parce que personne n'était disponible. Après avoir joué un peu là-bas, nous sommes allées chez ses amies pour livrer la carte d'anniversaire. Elles attendaient leur père parce qu'ils vont avoir une aventure avec une autre amie. Une fois que leur père était près de chez elles, j'ai récupéré ma fille et nous sommes rentrées parce que nous n'étions pas incluses parmi les invités. Ma fille a été très déçue, mais c'est la vie. Elle s'est encore barricadée dans sa chambre. Une fois qu'elle a eu faim, elle a réapparu. J'ai préparé des sushis pour son dîner. Après avoir fait ça, nous avons continué notre projet des montagnes russes LEGO, puis elle a finalement fait ses devoirs avec mon aide.

J'ai décrit mes expériences avec mon cours particulier de prononciation.

Nous avons terminé les montagnes russes de LEGO ! C'est incroyable, ce modèle. J'aime le mécanisme d'ascenseur.

J'ai édité les transcriptions des podcasts que j'ai téléchargés pour rassembler chaque phrase sur sa propre ligne pour faciliter la recherche. Il y avait des transcriptions qui n'ont pas été segmentées par phrase. Je les ai déplacées vers un autre dossier. J'ai aussi généré un logiciel pour analyser les transcriptions et faire une liste de lemmes par fréquence sauf les lemmes que je connais déjà.

J'ai fait une petite simulation pour notre régime de retraite en utilisant Emacs Lisp. Même si elle est peut-être trop simple, je le préfère aux sites commerciaux ou aux projets des autres parce que je comprends sa logique et je sais la fonction que je dois modifier si je veux une nouvelle fonctionnalité.

Ma fille et moi sommes allées au parc à vélo pour jouer avec son amie. Les filles ont réussi à monter la colline en chemin du retour.

Ma fille m'a dit qu'elle était prête à participer à l'école en ligne seule, donc je l'ai laissée et je me suis concentrée sur notre régime de retraite.

Ma fille a fait la grasse matinée. Elle a participé à l'école en ligne l'après-midi.

J'ai utilisé la reconnaissance vocale pour m'entraîner à réduire les mots de remplissage en anglais. C'était utile pour écrire des réponses aux soumissions et mon journal. Je peux ajuster le bras de mon microphone pour me permettre de dicter tout en m'étirant.

J'ai planifié un cours particulier avec un autre tuteur parce que mon tuteur habituel prend encore ses vacances la semaine prochaine.

J'ai géré des soumissions pour la conférence Emacs. J'ai regretté de ne pas avoir enregistré le processus pour trouver un arrangement qui permette d'observer toutes les contraintes de temps parce que j'adore le faire sur Emacs avec mon code que j'avais écrit il y a des années.

Mon mari et moi avons discuté de notre régime de retraite. Il a utilisé l'IA pour générer et modifier un logiciel pour simuler les chiffres.

J'ai eu une séance de conversation avec mon tuteur. Je lui ai posé des questions sur ses vacances la semaine prochaine. J'ai aussi décrit mon bricolage d'outils pour apprendre le français.

J'ai reçu la nouvelle pile pour mon ordinateur.

Oh non ! Le serveur de la réunion virtuelle n'a pas démarré pour OrgDevMeetup. Je dois analyser la cause.

Je suis épuisée. Ma fille et moi sommes allées au parc d'attractions. Nous avons essayé encore des montagnes russes. J'ai acheté le plan de nourriture, donc nous avons mangé du petit poulet frit, des frites, et un hotdog. Aujourd'hui nous avons fait les montagnes russes AlpenFury. C'était incroyable. C'était très rapide, très secouant. Nous avons attendu quatre-vingt-dix minutes, mais ça valait la peine.

Il faisait froid. Nous avons porté des pantalons et nos manteaux. Pendant que nous faisions les montagnes russes, j'avais envie de gants. Une fois rentrées, ma fille avait un peu froid.

J'ai acheté une bague qui peut contrôler mon téléphone ou mon ordinateur parce que je voudrais passer au fichier audio suivant.

J'ai apporté des aliments à mon ami et j'ai fait sa vaisselle.

Mon mari, ma fille et moi avons joué à Minecraft. Nous avons établi un atelier.

À l'heure du coucher, ma fille m'a posé des questions sur la neuroatypie.