ADHD is Awesome (2024) by Penn and Kim Holderness is a practical, positive, easy-to-read book on living with ADHD.

I find ADHD-oriented tips useful. My brain is prone to misplacing things, going off on tangents, and having attentional hiccups. Organizing my life around following my interests and minimizing commitments helps me increase happiness and reduce stress. Sketchnotes help me focus on what I'm learning and provide visual stimulation in my notes, making them more fun for me to review and share. I don't stock extras of things in a cabinet, but I do keep an Oops fund so I don't have to beat myself up over mistakes that cost a little money. I don't wear cargo pants, but I do wear vests with lots of pockets, a habit I picked up from my dad. I'm still working on developing that 15-minute reset habit, and on seeing and doing something about clutter.

As for the kiddo, there's no getting A+ to do things she's not interested in, and there's no holding her back if she's focused on something. Tips for parenting kids with ADHD also seem to work well for her: breaks, timers, taking advantage of hyperfocus, avoiding shame. My job is to:

• Practise connecting instead of correcting: Fretting at her doesn't accomplish anything. We work better when we feel connected.
• Explore and model things that work for me: I can show her how I use sketchnotes, checklists, timers, breaks, curiosity, learning, experimentation, self-compassion… Also, taking care of my sleep/exercise/happiness makes it easier to be the kind of parent I want to be.
• Help her learn how to figure things out for herself: I can help her navigate systems that aren't designed for her (like school) and figure out things that would work better for her.
• Frame things positively: Finding positive ways to frame our quirks can help with both self-image and other people's perceptions (chapter 4). Focusing on our strengths works better than beating ourselves up for our weaknesses. We still want to work around our weaknesses so they don't limit us, but might be able to use our strengths to do that.

The Hypercuriosity Theory of ADHD (and the paper) is also a good read that's somewhat related.

Dave Winer's looking for old school bloggers (also this) so that nudged me to think about how and why I blog.

(let* ((annotations '((2001 "university")
                      (2003 "graduated, teaching")
                      (2004 "internship in Japan")
                      (2005 "grad school")
                      (2007 "working at IBM")
                      (2008 "drawing")
                      (2012 "experiment with semi-retirement")
                      (2016 "A+ was born")
                      (2019 "EmacsConf, COVID-19")
                      (2022 "SuperNote A5X")
                      (2023 "even more EmacsConf automation")
                      (2024 "cargo bike")
                      (2025 "added iPad to the mix")))
       (json-array-type 'list)
       (json-object-type 'alist)
       (posts-by-year
        (mapcar
         (lambda (o) (cons (car o) (length (cdr o))))
         (seq-group-by
          (lambda (o) (substring (alist-get 'date o) 0 4))
          (json-read-file "~/proj/static-blog/_site/blog/all/index.json")))))
  (append
   '(("Year" "Posts" "Note") hline)
   (cl-loop
    for i from 2001 to 2025
    collect
    (list (format "[[https://sachachua.com/blog/%d][%d]]"
          i i)
          (alist-get (number-to-string i) posts-by-year nil nil #'string=)
          (or (car (alist-get i annotations)) "")))))

How long is a blog post? Some people write short posts with one clear thought. Others write longer essays.

I tend to start out writing a short post and then get distracted by all the rabbit-holes I want to go down. Drafting my thoughts on blogging leads to adding lots of blogs to my reader, writing some code that takes an OPML and makes a table of blogs and their most recent posts, fixing the org-html-themes setup for my Emacs configuration, breaking out this chunk as its own post, drawing a bunch of mindmaps, doing a braindump, tweaking my workflow for processing braindumps to use faster-whisper and whisper-ctranslate2 instead of WhisperX because of this issue, so that I can try the whisper-large-v3-turbo model, experimenting with workflows for reviewing the PDF on the iPad… Definitely lots of yak-shaving (wiktionary definition). I still want to write that post. I already have the sketch I want to include in it. It's like Chilli in the Bluey episode Sticky Gecko (script): "The door: It is right here. All we need to do is walk out of it: it's so easy!" The thought! It's right there! Just get to it, brain! But I wander because I wonder. I suppose that's all right.

It might be fun to play around with the sizes of things I share: shorter when my attention is fragmented or squirrely, longer when I can think about something over several days or years. Here are some ways to tinker with that.

Breaking thoughts down into smaller chunks so I can get them out the door:

• When I notice that something is a big blog post (like this reflection I've been working on about blogging), I can break out parts of it into their own blog posts and then replace that section with links.
• I can post interesting quotes and snippets to Mastodon and then round them up periodically or refer to them in blog posts. TODO: It might be good to have a shortcut for an accessible link to a toot using a speech bubble or similar icon.

Taming my tangents and ideas: I'm sometimes envious of blogs with neat side notes, but really, I should just accept that the tangents that my mind wants to go on can take paragraphs and are more suited to, say, collapsible details or a different blog post. Something I can experiment with: instead of gallivanting off on that tangent (soo hard to resist when there's an idea for an Emacs tweak!), I can add a TODO and leave it for my future self. Maybe even two TODOs: one inline, where it makes sense in the text; and one in my Org Mode, with a link to the blog post so that I can go back and update it when (if!) I get around to it. Who knows, maybe someone might comment with something that already exists.

Saving scraps: It's easier to cut out half-fleshed-out ideas if I tell myself I'm just saving them somewhere. Right now I capture/refile them to a scraps heading, but there's probably a better way to handle this. Maybe I can post some thoughts to Mastodon and then save the toot URL. Maybe I can experiment with using Denote to manage private notes.

Connecting thoughts and building them up:

• I tend to write in small chunks. (TODO: I could probably do some kind of word-count analysis, might be neat.) Sketchnotes and hyperlinks might help me chunk thoughts so I can think about bigger things. I can link to paragraphs and text fragments, so I can connect thoughts with other parts of thoughts instead of trying to get the granularity right the first time around. The shortcuts I made for linking to blog posts and searching the Web or my notes are starting to help.
• I sporadically work on topic maps or indices. Maybe I'll gradually flesh them out into a digital garden / personal wiki.
• Sometimes I don't remember the exact words I used. Probabilistic search or vector search might help here, too. I don't need an AI-generated summary, I just want a list of related posts.
• I can figure out how to add backlinks to my blog, or simplify the workflow for adding links to previous posts. Maybe something based on this guide for 11ty or binyamin/eleventy-plugin-backlinks. I might need to write something custom anyway so that I can ignore the links coming from monthly/weekly review posts.

Connecting to other people's thoughts: For the purposes of conversation, it'll probably be good to let people know if I write something about their blog post. Doesn't happen automatically. Pingbacks and referrer logs got too swamped by spam a long time ago, so I don't think anyone really uses them. Idea: It might be neat to have something that quickly lists all the external links in a post, and maybe a way to save the e-mail addresses or Mastodon handles for people after I look them up so that I can make that even smoother, and some kind of quick template. I can send email and toot from within Emacs, so that's totally doable… (No, I am not going to write it right now, I'm going to add it to my to-do list.)

(Also, there's another thought here about books and The Great Conversation, and blogs and smaller-scale conversations, and William Thurston and mathematicians and understanding, and cafes…)

Hmm. I think that getting my brain to make smaller chunks and get them out the door will be a good thing to focus on. Synthesizing can come later.

Related:

• Old-school blogger

Nudged by Dave Winer's post about old-school bloggers and my now-nicely-synchronizing setup of NetNewsWire (iOS) and FreshRSS (web), I gave Claude AI this prompt to list bloggers (with the addition of "Please include URLs and short bios.") and had fun going through the list it produced. A number of people were no longer blogging (unreachable sites or inactive blogs), but I found a few that I wanted to add to my feed reader.

Here is my people.opml at the moment (slightly redacted, as I read my husband's blog as well). This list has some non-old-school bloggers as well and some sketchnoters, but that's fine. It's a very tiny slice of the awesomeness of the Internet out there, definitely not exhaustive, just a start. I've been adding more by trawling through indieblog.page and the occasional interesting post on news.ycombinator.com.

It makes sense to make an HTML version to make it easier for people to explore, like those old-fashioned blog rolls. Ooh, maybe some kind of table like indieblog.page, listing a recent item from each blog. (I am totally not surprised about my tendency to self-nerd-snipe with some kind of Emacs thing.) This uses my-opml-table and my-rss-get-entries, which I have just added to my Emacs configuration.

(defun my-opml-table (xml)
  (sort
   (mapcar
    (lambda (o)
      (let ((latest (car (condition-case nil (my-rss-get-entries (dom-attr o 'xmlUrl))
                           (error nil)))))
        (list
         (if latest
             (format-time-string "%Y-%m-%d" (plist-get latest :date))
           "")
         (org-link-make-string
          (or (dom-attr o 'htmlUrl)
              (dom-attr o 'xmlUrl))
          (replace-regexp-in-string " *|" "" (dom-attr o 'text)))
         (if latest
             (org-link-make-string
              (plist-get latest :url)
              (or (plist-get latest :title) "(untitled)"))
           ""))))
    (dom-search
     xml
     (lambda (o)
       (and
        (eq (dom-tag o) 'outline)
        (dom-attr o 'xmlUrl)
        (dom-attr o 'text)))))
   :key #'car
   :reverse t))

(defun my-rss-get-entries (url)
  "Return a list of the form ((:title ... :url ... :date ...) ...)."
  (with-current-buffer (url-retrieve-synchronously url)
    (set-buffer-multibyte t)
    (goto-char (point-min))
    (when (re-search-forward "<\\?xml\\|<rss" nil t)
      (goto-char (match-beginning 0))
      (sort
       (let* ((feed (xml-parse-region (point) (point-max)))
              (is-rss (> (length (xml-get-children (car feed) 'entry)) 0)))
         (if is-rss
             (mapcar
              (lambda (entry)
                (list
                 :url
                 (or
                  (xml-get-attribute
                   (car
                    (or
                     (seq-filter (lambda (x) (string= (xml-get-attribute x 'rel) "alternate"))
                                 (xml-get-children entry 'link))
                     (xml-get-children entry 'link)))
                   'href)
                  (dom-text (dom-by-tag entry 'guid)))
                 :title
                 (elt (car (xml-get-children entry 'title)) 2)
                 :date
                 (date-to-time (elt (car (xml-get-children entry 'updated)) 2))))
              (xml-get-children (car feed) 'entry))
           (mapcar (lambda (entry)
                     (list
                      :url
                      (or (caddr (car (xml-get-children entry 'link)))
                          (dom-text (dom-by-tag entry 'guid)))
                      :title
                      (caddr (car (xml-get-children entry 'title)))
                      :date
                      (date-to-time (elt (car (xml-get-children entry 'pubDate)) 2))))
                   (xml-get-children (car (xml-get-children (car feed) 'channel)) 'item))))
       :key (lambda (o) (plist-get o :date))
       :lessp #'time-less-p
       :reverse t))))

(my-opml-table (xml-parse-file "~/Downloads/people.opml"))

I'm rebuilding my feed list from scratch. I want to read more. I read the aggregated feeds at planet.emacslife.com every week as part of preparing Emacs News. Maybe I'll go over the list of blogs I aggregate there, widen it to include all posts instead of just Emacs-specific ones, and see what resonates. Emacs people tend to be interesting. Here is an incomplete list based on people who've posted in the past two years or so, based on this work-in-progress planetemacslife-expanded.opml. (I haven't tweaked all the URLs yet. I stopped at around 2023 and made the rest of the elements xoutline instead of outline so that my code would skip them.)

(my-opml-table (xml-parse-file "~/Downloads/planetemacslife-expanded.opml"))

Making this table was fun. It's nice to see a lot of people also writing and learning out loud. This reminded me a little of EmacsConf - 2020 - talks - Sharing blogs (and more) with org-webring. TODO: Could be fun to have a blogroll page again.

I notice I tend to like:

• posts about adapting technology to personal interests, more than posts about the industry or generalizations
• detailed posts about things I'm currently interested in (Emacs, personal knowledge management, some Javascript), more than detailed tech posts about things I've decided not to get into at the moment
• "I" posts more than "You" posts: personal reflections rather than didactic advice
• curiosity, fun, experimentation

Looking forward to discovering more!

Related:

• Old-school blogger

I usually summarize Mastodon links, move them to my Emacs News Org file, and then categorize them. Today I accidentically categorized the links while they were still in my Mastodon buffer, so I had two lists with categories. I wanted to write some Emacs Lisp to merge sublists based on the top-level items. I could sort the list alphabetically with C-c ^ (org-sort) and then delete the redundant top-level item lines, but it's fun to tinker with Emacs Lisp.

Example input:

• Topic A:
  • Item 1
  • Item 2
    • Item 2.1
• Topic B:
  • Item 3
• Topic A:
  • Item 4
    • Item 4.1

Example output:

• Topic B:
  • Item 3
• Topic A:
  • Item 1
  • Item 2
    • Item 2.1
  • Item 4
    • Item 4.1

The sorting doesn't particularly matter to me, but I want the things under Topic A to be combined. Someday it might be nice to recursively merge other entries (ex: if there's another "Topic A: - Item 2" subitem like "Item 2.2"), but I don't need that yet.

Anyway, we can parse the list with org-list-to-lisp (which can even delete the original list) and recreate it with org-list-to-org, so then it's a matter of transforming the data structure.

(defun my-org-merge-list-entries-at-point ()
  "Merge entries in a nested Org Mode list at point that have the same top-level item text."
  (interactive)
  (save-excursion
    (let* ((list-indentation (save-excursion
                               (goto-char (caar (org-list-struct)))
                               (current-indentation)))
           (list-struct (org-list-to-lisp t))
           (merged-list (my-org-merge-list-entries list-struct)))
      (insert (org-ascii--indent-string (org-list-to-org merged-list) list-indentation)
              "\n"))))

(defun my-org-merge-list-entries (list-struct)
  "Merge an Org list based on its top-level headings"
  (cons (car list-struct)
        (mapcar
         (lambda (g)
           (list
            (car g)
            (let ((list-type (car (car (cdr (car (cdr g))))))
                  (entries (seq-mapcat #'cdar (mapcar #'cdr (cdr g)))))
              (apply #'append (list list-type) entries nil))))
         (seq-group-by #'car (cdr list-struct)))))

A couple of test cases:

(ert-deftest my-org-merge-list-entries ()
  (should
   (equal
    (my-org-merge-list-entries
     '(unordered ("Topic B:" (unordered ("Item 3")))))
    '(unordered ("Topic B:" (unordered ("Item 3"))))))
  (should
   (equal
    (my-org-merge-list-entries
     '(unordered ("Topic B:" (unordered ("Item 3")))
                 ("Topic A:"
                  (unordered ("Item 1")
                             ("Item 2"
                              (unordered ("Item 2.1")))))
                 ("Topic A:"
                  (unordered
                   ("Item 4" (unordered ("Item 4.1")))))))
    '(unordered
      ("Topic B:" (unordered ("Item 3")))
      ("Topic A:"
       (unordered ("Item 1")
                  ("Item 2" (unordered ("Item 2.1")))
                  ("Item 4" (unordered ("Item 4.1")))))))))

(defun my-org-package-export (link description format &optional arg)
  (let* ((package-info (car (assoc-default (intern link) package-archive-contents)))
         (package-source (and package-info (package-desc-archive package-info)))
         (path (format
                (cond
                 ((null package-source) link)
                 ((string= package-source "gnu") "https://elpa.gnu.org/packages/%s.html")
                 ((string= package-source "melpa") "https://melpa.org/#/%s")
                 ((string= package-source "nongnu") "https://elpa.nongnu.org/nongnu/%s.html")
                 (t (error 'unknown-source)))
                link))
         (desc (or description link)))
    (if package-source
        (cond
         ((eq format '11ty) (format "<a target=\"_blank\" href=\"%s\">%s</a>" path desc))
         ((eq format 'html) (format "<a target=\"_blank\" href=\"%s\">%s</a>" path desc))
         ((eq format 'wp) (format "<a target=\"_blank\" href=\"%s\">%s</a>" path desc))
         ((eq format 'latex) (format "\\href{%s}{%s}" path desc))
         ((eq format 'texinfo) (format "@uref{%s,%s}" path desc))
         ((eq format 'ascii) (format "%s <%s>" desc path))
         ((eq format 'org) (org-link-make-string (concat "package:" link) description)) ;; added this line
         (t path))
      desc)))

• Upcoming events (iCal file, Org):
  • M-x Research: TBA https://m-x-research.github.io/ Wed Mar 19 0900 America/Vancouver - 1100 America/Chicago - 1200 America/Toronto - 1600 Etc/GMT - 1700 Europe/Berlin - 2130 Asia/Kolkata – Thu Mar 20 0000 Asia/Singapore
  • Emacs APAC: Emacs APAC meetup (virtual) https://emacs-apac.gitlab.io/announcements/ Sat Mar 22 0130 America/Vancouver - 0330 America/Chicago - 0430 America/Toronto - 0830 Etc/GMT - 0930 Europe/Berlin - 1400 Asia/Kolkata - 1630 Asia/Singapore
  • EmacsSF (in person): coffee.el in SF https://www.meetup.com/emacs-sf/events/306610734/ Sat Mar 22 1100 America/Los_Angeles
  • Emacs Berlin (hybrid, in English) https://emacs-berlin.org/ Wed Mar 26 1030 America/Vancouver - 1230 America/Chicago - 1330 America/Toronto - 1730 Etc/GMT - 1830 Europe/Berlin - 2300 Asia/Kolkata – Thu Mar 27 0130 Asia/Singapore
• Emacs 30:
  • emacs-mac v30 experimental build: seeking experienced contributors/testers
  • emacs-30.1-on-android-termux-vs-android-linux-terminal.txt — paste.sr.ht (@gnomon@mastodon.social)
  • Emacs 30 Now On Android - fossHQ
  • EmacsWiki: Emacs On Android
• Beginner:
  • Editing Files with Emacs (11:29)
  • GNU Emacs má 40 let (Tomáš Čech) (23:23)
  • Emacs என்பது யாதெனில் - அத்தியாயம் ஒன்று - Sakhil (01:00:55)
• Emacs configuration:
  • inhibit-mouse.el - A package for disabling the mouse in Emacs (Release: 1.0.1) (Reddit)
  • Dotfiles Check-Up: Emacs and Guix Tweaks - System Crafters Live! (01:38:38)
  • sss config: everfrost theme support (@sss_project@mastodon.social)
• Emacs Lisp:
  • New package raq.el: HTTP Library Adapter for Emacs, suport url.el and plz.el, and can be extended. (Reddit)
  • compile-angel - Ensure all Elisp files are both Byte and Native-Compiled (Alternative to: auto-compile) - Release 1.0.6 (Reddit)
  • tip about get-mru-window (most recently used)
  • Some problems of modernizing Emacs (incomplete - slides 0 to 6 only) (20:39)
• Appearance:
  • Tip about using consult-theme from the consult package to preview themes quickly
  • Announcing Calle 24 (Reddit, Irreal) - substitutes the default tool bar icons with those from SF Symbols, a library of images provided by Apple
  • tomorrow-night-deepblue-theme (Release 1.2.1): A deep blue Emacs theme, inspired by the Tomorrow Night theme
  • My Unique Emacs Theme Pack – Now Available for Download! (Reddit) - screenshots are in the Details heading
• Navigation:
  • Noether: global minor mode managing user-defined posframe Views (Reddit)
  • easysession.el 1.1.3: Persist and restore Emacs sessions including frames, tab-bar, buffers, indirect buffers, Dired, and window splits (Reddit)
  • The Emacs recursive narrow package #coding #programming (02:41)
  • A tutorial on 2 Columns in Emacs #emacs #coding #programming (11:32)
• Writing:
  • Hugo-Heagren/clever-cite: format quoted text as you kill/yank between buffers (@HugoHeagren@scholar.social)
  • quick-sdcv.el (Release 1.0.1): Turn Emacs into an offline dictionary with sdcv (Reddit)
  • Editing Overleaf Documents with Emacs | Valentin Boettcher (Reddit) - nice! live editing, might be useful for collaboration too
  • Chung-hong Chan: Miscellaneous talk #45 Quarto guy, Overleaf’s markdown mode?, Flymake, Mailing lists, CRAN - ESS also
  • Wherein I Explain Why Emacs Is The Best Tool For WordPress (Reddit)
  • Meet Harper | A Grammarly Alternative for Neovim | Emacs, Obsidian, Zed, VScode and Helix (deez) (21:16)
• Org Mode:
  • Using Emacs Org mode to manage my appointments
  • Calendar.org (Reddit)
  • Org-anizing My Fragrance Collection with Emacs – literatelisp.eu (@theesm@social.tchncs.de)
  • Sacha Chua: Remove open Org Mode clock entries
  • a template for writing OWL ontologies as Org Mode documents, with supporting functions and scripts
  • org-expose-emphasis-markers: A new package used to automatically show hidden emphasis markers at point in org mode when `org-hide-emphasis-markers` is on. (Reddit)
  • Seam: personal wiki system based on Org mode (@spnw@gts.plexwave.org)
  • Using an Org-mode README on SourceHut (@tiang@mastodon.social)
• Denote:
  • Protesilaos Stavrou: Emacs: Denote is becoming many packages
• Coding:
  • using hideshow minor mode in all programming modes so you can toggle code sections (@dotemacs@mastodon.xyz)
  • Announcing Casual Make (Reddit, Irreal)
  • eglot-inactive-regions - eglot extension to dim inactive preprocessor branches - release: 0.6.4 (Reddit)
  • I found an easy way to make code comments appear in other mode's syntax
  • A story of mystery involving LS, clangd and a very easy fix
  • flymake-bashate.el (1.0.2) - A Flymake backend for bashate: Real-time style checking for Bash shell scripts
  • Bozhidar Batsov: neocaml: a new Emacs package for OCaml programming
  • swyddfa/esbonio.el: Integrating the esbonio language server into Emacs (@alcarney@fosstodon.org)
• Mail, news, and chat:
  • twtxt.el updates: notifications, user interface, fixes (@andros@activity.andros.dev)
• AI:
  • gptel 0.9.8 released (tool-use, support for "reasoning" output, dry-run options and more) (Reddit)
  • gptel-aibo update: new complete at point
  • GitHub - rajp152k/fabric-gpt.el: Fabric Prompts for emacs gpt.el
  • Aidermacs v1.0 Released. Available Now on Melpa and Non-GNU Elpa! (Reddit) (also 0.5.0 discussion)
  • James Dyer: Ollama-Buddy 0.8.0 - Added System Prompts, Model Info and simpler menu model assignment
  • James Dyer: Ollama-Buddy 0.7.1 - Org-mode Chat, Parameter Control and JSON Debugging
  • claude-code.el (Reddit)
  • lizqwerscott/mcp.el: An Mcp client inside Emacs (Reddit) - model context protocol servers
  • Introducing forge-llm: Generate PR descriptions automatically with LLMs in Emacs Forge
• Community:
  • Fortnightly Tips, Tricks, and Questions — 2025-03-11 / week 10
  • Eric MacAdie: 2025-03 Austin Emacs Meetup
  • Irreal: From Neovim to Emacs
• Other:
  • Bible Verse of the Day as Emacs dashboard footer
  • gtd-E: new GTD app (Reddit)
  • SYD-EMACS(1): sandboxed editor environments (@alip@mastodon.online)
• Emacs development:
  • emacs-devel:
    • Improving the Tools menu
    • Re: Semantic: update or remove?
      • Re: Semantic: update or remove? - more thoughts on tree-sitter and the Emacs ecosystem
    • Re: Markers in a gap array - sorted array with gap
  • Make marking conflicted files as resolved upon saving opt-out
  • ; Add NEWS entry for java-ts-mode-method-chaining-indent-offset
  • ; etc/NEWS (remember-prefix-map): Suggest a key reserved to users.
  • New project-save-some-buffers command
  • Add a new command `speedbar-window'.
  • dired-copy-filename-as-kill: Support project-relative names
  • Make turn-on-flyspell/turn-off-flyspell obsolete
  • Improve tramp-*-with-sudo commands
  • ; * etc/NEWS: Announce the larger number of sub-processes on w32.
  • New configure option –with-systemduserunitdir
  • Allow control of indicating empty rectangular selections
  • Turn 'remember-mode' into a minor mode
  • diff-apply-buffer now considers the region and can reverse-apply.
  • Fix capitalization ELisp -> Elisp
  • Automatically document when setopt is needed
  • New user option follow-mode-prefix-key
  • Remove variable aliases obsolete since Emacs 23.2
  • New user variable `exchange-point-and-mark-highlight-region`
• New packages:
  • aider: Interact with Aider: AI pair programming made simple (MELPA)
  • company-forge: Company backend for assignees and topics from forge (MELPA)
  • denote-journal: Convenience functions for daily journaling with Denote (GNU ELPA)
  • denote-markdown: Extensions that better integrate Denote with Markdown (GNU ELPA)
  • denote-org: Denote extensions for Org mode (GNU ELPA)
  • denote-sequence: Sequence notes or Folgezettel with Denote (GNU ELPA)
  • denote-silo: Convenience functions for using Denote in multiple silos (GNU ELPA)
  • indexed: Cache metadata on all Org files (MELPA)
  • jira: Emacs Interface to Jira (MELPA)
  • ob-aider: Org Babel functions for Aider.el integration (MELPA)
  • org-expose-emphasis-markers: Automatically show hidden org emphasis markers (MELPA)

Links from reddit.com/r/emacs, r/orgmode, r/spacemacs, r/planetemacs, Mastodon #emacs, Bluesky #emacs, Hacker News, lobste.rs, programming.dev, lemmy.world, lemmy.ml, planet.emacslife.com, YouTube, the Emacs NEWS file, Emacs Calendar, and emacs-devel. Thanks to Andrés Ramírez for emacs-devel links. Do you have an Emacs-related link or announcement? Please e-mail me at sacha@sachachua.com. Thank you!

Pedro pointed out that I had some incomplete clock entries in my Emacs configuration. org-resolve-clocks prompts you for what to do with each open clock entry in your Org agenda files and whatever Org Mode files you have open.

If you don't feel like cancelling each clock with C, I also wrote this function to delete all open clocks in the current file.

(defun my-org-delete-open-clocks ()
  (interactive)
  (flush-lines
   (rx
    line-start
    (zero-or-more space)
    "CLOCK:"
    (one-or-more space)
    (regexp org-ts-regexp-inactive)
    (zero-or-more space)
    line-end)))